Merge pull request #1314 from christianguenter2/ECSD

ECSD eCATT System Data Container serialization

src/objects/ecatt/zcl_abapgit_ecatt_system_downl.clas.abap

@@ -0,0 +1,138 @@
+CLASS zcl_abapgit_ecatt_system_downl DEFINITION
+  PUBLIC
+  INHERITING FROM cl_apl_ecatt_systems_download
+  CREATE PUBLIC .
+
+  PUBLIC SECTION.
+    METHODS:
+      download REDEFINITION,
+
+      get_xml_stream
+        RETURNING
+          VALUE(rv_xml_stream) TYPE xstring,
+
+      get_xml_stream_size
+        RETURNING
+          VALUE(rv_xml_stream_size) TYPE int4.
+
+  PROTECTED SECTION.
+    METHODS:
+      download_data REDEFINITION.
+
+  PRIVATE SECTION.
+    DATA:
+      mv_xml_stream      TYPE xstring,
+      mv_xml_stream_size TYPE int4.
+
+    METHODS:
+      set_systems_data_to_template.
+
+ENDCLASS.
+
+
+CLASS zcl_abapgit_ecatt_system_downl IMPLEMENTATION.
+
+  METHOD download.
+
+    " Downport
+
+    DATA: lv_partyp TYPE string.
+
+    load_help = im_load_help.
+    typ = im_object_type.
+
+    TRY.
+        cl_apl_ecatt_object=>show_object(
+          EXPORTING
+            im_obj_type = im_object_type
+            im_name     = im_object_name
+            im_version  = im_object_version
+          IMPORTING
+            re_object   = ecatt_object ).
+      CATCH cx_ecatt INTO ex_ecatt.
+        RETURN.
+    ENDTRY.
+
+    lv_partyp = cl_apl_ecatt_const=>params_type_par.
+
+* build_schema( ).
+* set_attributes_to_schema( ).
+    set_attributes_to_template( ).
+* set_systems_data_to_schema( ).
+    set_systems_data_to_template( ).
+* download_schema( ).
+    download_data( ).
+
+  ENDMETHOD.
+
+
+  METHOD download_data.
+
+    " Downport
+
+    zcl_abapgit_ecatt_helper=>download_data(
+      EXPORTING
+        ii_template_over_all = template_over_all
+      IMPORTING
+        ev_xml_stream        = mv_xml_stream
+        ev_xml_stream_size   = mv_xml_stream_size ).
+
+  ENDMETHOD.
+
+
+  METHOD get_xml_stream.
+
+    rv_xml_stream = mv_xml_stream.
+
+  ENDMETHOD.
+
+
+  METHOD get_xml_stream_size.
+
+    rv_xml_stream_size = mv_xml_stream_size.
+
+  ENDMETHOD.
+
+
+  METHOD set_systems_data_to_template.
+
+    DATA: lo_ecatt_systems TYPE REF TO cl_apl_ecatt_system_data,
+          lt_sys_data      TYPE etsys_def_tabtype,
+          ls_sys_data      TYPE etsys_def,
+          li_item          TYPE REF TO if_ixml_element,
+          li_sysdata_node  TYPE REF TO if_ixml_element.
+
+    lo_ecatt_systems ?= ecatt_object.
+    lt_sys_data = lo_ecatt_systems->get_system_data( ).
+
+    li_sysdata_node = template_over_all->create_simple_element(
+                        name = 'SYSTEMS_DATA'
+                        parent = root_node ).
+
+    etpar_node = template_over_all->create_simple_element(
+                   name = 'ETSYS_DEF'
+                   parent = li_sysdata_node ).
+
+    LOOP AT lt_sys_data INTO ls_sys_data.
+
+      CLEAR: ls_sys_data-sys_desc, ls_sys_data-instance.
+
+      CALL FUNCTION 'SDIXML_DATA_TO_DOM'
+        EXPORTING
+          name         = 'item'
+          dataobject   = ls_sys_data
+        IMPORTING
+          data_as_dom  = li_item
+        CHANGING
+          document     = template_over_all
+        EXCEPTIONS
+          illegal_name = 1
+          OTHERS       = 2.
+
+      etpar_node->append_child( new_child = li_item ).
+
+    ENDLOOP.
+
+  ENDMETHOD.
+
+ENDCLASS.

src/objects/ecatt/zcl_abapgit_ecatt_system_downl.clas.xml

@@ -0,0 +1,18 @@
+<?xml version="1.0" encoding="utf-8"?>
+<abapGit version="v1.0.0" serializer="LCL_OBJECT_CLAS" serializer_version="v1.0.0">
+ <asx:abap xmlns:asx="http://www.sap.com/abapxml" version="1.0">
+  <asx:values>
+   <VSEOCLASS>
+    <CLSNAME>ZCL_ABAPGIT_ECATT_SYSTEM_DOWNL</CLSNAME>
+    <VERSION>1</VERSION>
+    <LANGU>E</LANGU>
+    <DESCRIPT>zcl_abapgit_ecatt_download</DESCRIPT>
+    <EXPOSURE>2</EXPOSURE>
+    <STATE>1</STATE>
+    <CLSCCINCL>X</CLSCCINCL>
+    <FIXPT>X</FIXPT>
+    <UNICODE>X</UNICODE>
+   </VSEOCLASS>
+  </asx:values>
+ </asx:abap>
+</abapGit>

src/objects/ecatt/zcl_abapgit_ecatt_system_upl.clas.abap

@@ -0,0 +1,41 @@
+CLASS zcl_abapgit_ecatt_system_upl DEFINITION
+  PUBLIC
+  INHERITING FROM cl_apl_ecatt_systems_upload
+  FINAL
+  CREATE PUBLIC .
+
+  PUBLIC SECTION.
+    METHODS:
+      z_set_stream_for_upload
+        IMPORTING
+          im_xml TYPE xstring.
+
+  PROTECTED SECTION.
+    METHODS:
+      upload_data_from_stream REDEFINITION.
+
+  PRIVATE SECTION.
+    DATA: mv_external_xml TYPE xstring.
+
+ENDCLASS.
+
+
+
+CLASS zcl_abapgit_ecatt_system_upl IMPLEMENTATION.
+
+  METHOD upload_data_from_stream.
+
+    " Downport
+    template_over_all = zcl_abapgit_ecatt_helper=>upload_data_from_stream( mv_external_xml ).
+
+  ENDMETHOD.
+
+
+  METHOD z_set_stream_for_upload.
+
+    " downport from CL_APL_ECATT_SYSTEMS_UPLOAD SET_STREAM_FOR_UPLOAD
+    mv_external_xml = im_xml.
+
+  ENDMETHOD.
+
+ENDCLASS.

src/objects/ecatt/zcl_abapgit_ecatt_system_upl.clas.xml

@@ -0,0 +1,19 @@
+<?xml version="1.0" encoding="utf-8"?>
+<abapGit version="v1.0.0" serializer="LCL_OBJECT_CLAS" serializer_version="v1.0.0">
+ <asx:abap xmlns:asx="http://www.sap.com/abapxml" version="1.0">
+  <asx:values>
+   <VSEOCLASS>
+    <CLSNAME>ZCL_ABAPGIT_ECATT_SYSTEM_UPL</CLSNAME>
+    <VERSION>1</VERSION>
+    <LANGU>E</LANGU>
+    <DESCRIPT>ZCL_APL_ECATT_DATA_UPLOAD</DESCRIPT>
+    <EXPOSURE>2</EXPOSURE>
+    <STATE>1</STATE>
+    <CLSFINAL>X</CLSFINAL>
+    <CLSCCINCL>X</CLSCCINCL>
+    <FIXPT>X</FIXPT>
+    <UNICODE>X</UNICODE>
+   </VSEOCLASS>
+  </asx:values>
+ </asx:abap>
+</abapGit>

src/objects/zcl_abapgit_object_ecsd.clas.abap

@@ -0,0 +1,54 @@
+CLASS zcl_abapgit_object_ecsd DEFINITION
+  PUBLIC
+  INHERITING FROM zcl_abapgit_object_ecatt_super
+  FINAL
+  CREATE PUBLIC .
+
+  PUBLIC SECTION.
+
+    METHODS:
+      constructor
+        IMPORTING
+          !is_item     TYPE zif_abapgit_definitions=>ty_item
+          !iv_language TYPE spras.
+
+  PROTECTED SECTION.
+    METHODS:
+      get_object_type REDEFINITION,
+      get_upload REDEFINITION,
+      get_download REDEFINITION.
+
+ENDCLASS.
+
+
+
+CLASS zcl_abapgit_object_ecsd IMPLEMENTATION.
+
+
+  METHOD constructor.
+
+    super->constructor( is_item     = is_item
+                        iv_language = iv_language ).
+
+  ENDMETHOD.
+
+
+  METHOD get_object_type.
+
+    rv_object_type = cl_apl_ecatt_const=>obj_type_system_data.
+
+  ENDMETHOD.
+
+  METHOD get_upload.
+
+    CREATE OBJECT ro_upload TYPE zcl_abapgit_ecatt_system_upl.
+
+  ENDMETHOD.
+
+  METHOD get_download.
+
+    CREATE OBJECT ro_download TYPE zcl_abapgit_ecatt_system_downl.
+
+  ENDMETHOD.
+
+ENDCLASS.

src/objects/zcl_abapgit_object_ecsd.clas.xml

@@ -0,0 +1,18 @@
+<?xml version="1.0" encoding="utf-8"?>
+<abapGit version="v1.0.0" serializer="LCL_OBJECT_CLAS" serializer_version="v1.0.0">
+ <asx:abap xmlns:asx="http://www.sap.com/abapxml" version="1.0">
+  <asx:values>
+   <VSEOCLASS>
+    <CLSNAME>ZCL_ABAPGIT_OBJECT_ECSD</CLSNAME>
+    <VERSION>1</VERSION>
+    <LANGU>E</LANGU>
+    <EXPOSURE>2</EXPOSURE>
+    <STATE>1</STATE>
+    <CLSFINAL>X</CLSFINAL>
+    <CLSCCINCL>X</CLSCCINCL>
+    <FIXPT>X</FIXPT>
+    <UNICODE>X</UNICODE>
+   </VSEOCLASS>
+  </asx:values>
+ </asx:abap>
+</abapGit>