mirror of
https://github.com/abapGit/abapGit.git
synced 2025-04-30 20:03:20 +08:00
257 lines
6.5 KiB
ABAP
257 lines
6.5 KiB
ABAP
CLASS zcl_abapgit_objects_bridge DEFINITION PUBLIC FINAL CREATE PUBLIC INHERITING FROM zcl_abapgit_objects_super.
|
|
|
|
PUBLIC SECTION.
|
|
|
|
METHODS constructor
|
|
IMPORTING is_item TYPE zif_abapgit_definitions=>ty_item
|
|
RAISING cx_sy_create_object_error.
|
|
|
|
INTERFACES zif_abapgit_object.
|
|
PROTECTED SECTION.
|
|
PRIVATE SECTION.
|
|
DATA mo_plugin TYPE REF TO object.
|
|
|
|
CLASS-METHODS initialize.
|
|
|
|
" Metadata flags (late_deser, delete_tadir, and ddic) are not required by abapGit anymore
|
|
" We keep them to stay compatible with old bridge implementation
|
|
TYPES:
|
|
BEGIN OF ty_metadata,
|
|
class TYPE string,
|
|
version TYPE string,
|
|
late_deser TYPE abap_bool,
|
|
delete_tadir TYPE abap_bool,
|
|
ddic TYPE abap_bool,
|
|
END OF ty_metadata .
|
|
|
|
TYPES: BEGIN OF ty_s_objtype_map,
|
|
obj_typ TYPE tadir-object,
|
|
plugin_class TYPE seoclsname,
|
|
END OF ty_s_objtype_map,
|
|
ty_t_objtype_map TYPE SORTED TABLE OF ty_s_objtype_map WITH UNIQUE KEY obj_typ.
|
|
|
|
CLASS-DATA gv_init TYPE abap_bool.
|
|
CLASS-DATA gt_objtype_map TYPE ty_t_objtype_map.
|
|
|
|
ENDCLASS.
|
|
|
|
|
|
|
|
CLASS zcl_abapgit_objects_bridge IMPLEMENTATION.
|
|
|
|
|
|
METHOD initialize.
|
|
|
|
DATA lt_plugin_class TYPE STANDARD TABLE OF seoclsname WITH DEFAULT KEY.
|
|
DATA lv_plugin_class LIKE LINE OF lt_plugin_class.
|
|
DATA lo_plugin TYPE REF TO object.
|
|
DATA lt_plugin_obj_type TYPE STANDARD TABLE OF tadir-object WITH DEFAULT KEY.
|
|
DATA ls_objtype_map LIKE LINE OF gt_objtype_map.
|
|
|
|
IF gv_init = abap_true.
|
|
RETURN.
|
|
ENDIF.
|
|
gv_init = abap_true.
|
|
|
|
SELECT clsname
|
|
FROM seometarel
|
|
INTO TABLE lt_plugin_class
|
|
WHERE refclsname LIKE 'ZCL_ABAPGITP_OBJECT%'
|
|
AND version = '1'
|
|
ORDER BY clsname. "#EC CI_SUBRC
|
|
|
|
CLEAR gt_objtype_map.
|
|
LOOP AT lt_plugin_class INTO lv_plugin_class
|
|
WHERE table_line <> 'ZCL_ABAPGITP_OBJECT_BY_SOBJ'.
|
|
* have the generic plugin only as fallback
|
|
TRY.
|
|
CREATE OBJECT lo_plugin TYPE (lv_plugin_class).
|
|
CATCH cx_sy_create_object_error.
|
|
CONTINUE. ">>>>>>>>>>>>>>
|
|
ENDTRY.
|
|
|
|
CALL METHOD lo_plugin->('GET_SUPPORTED_OBJ_TYPES')
|
|
IMPORTING
|
|
rt_obj_type = lt_plugin_obj_type.
|
|
|
|
ls_objtype_map-plugin_class = lv_plugin_class.
|
|
LOOP AT lt_plugin_obj_type INTO ls_objtype_map-obj_typ.
|
|
INSERT ls_objtype_map INTO TABLE gt_objtype_map.
|
|
IF sy-subrc <> 0.
|
|
* No exception in class-contructor possible.
|
|
* Anyway, a shortdump is more appropriate in this case
|
|
ASSERT 'There must not be' =
|
|
|multiple abapGit-Plugins for the same object type {
|
|
ls_objtype_map-obj_typ }|.
|
|
ENDIF.
|
|
ENDLOOP.
|
|
ENDLOOP. "at plugins
|
|
|
|
* and the same for the generic plugin if exists
|
|
* have the generic plugin only as fallback
|
|
LOOP AT lt_plugin_class INTO lv_plugin_class
|
|
WHERE table_line = 'ZCL_ABAPGITP_OBJECT_BY_SOBJ'.
|
|
CREATE OBJECT lo_plugin TYPE (lv_plugin_class).
|
|
|
|
CALL METHOD lo_plugin->('GET_SUPPORTED_OBJ_TYPES')
|
|
RECEIVING
|
|
rt_obj_type = lt_plugin_obj_type.
|
|
|
|
ls_objtype_map-plugin_class = lv_plugin_class.
|
|
LOOP AT lt_plugin_obj_type INTO ls_objtype_map-obj_typ.
|
|
INSERT ls_objtype_map INTO TABLE gt_objtype_map. "knowingly ignore the subrc
|
|
ENDLOOP.
|
|
ENDLOOP. "at plugins
|
|
|
|
ENDMETHOD.
|
|
|
|
|
|
METHOD constructor.
|
|
|
|
DATA ls_objtype_map LIKE LINE OF gt_objtype_map.
|
|
|
|
super->constructor( is_item = is_item
|
|
iv_language = zif_abapgit_definitions=>c_english ).
|
|
|
|
initialize( ).
|
|
|
|
* determine the responsible plugin
|
|
READ TABLE gt_objtype_map INTO ls_objtype_map
|
|
WITH TABLE KEY obj_typ = is_item-obj_type.
|
|
IF sy-subrc = 0.
|
|
CREATE OBJECT mo_plugin TYPE (ls_objtype_map-plugin_class).
|
|
|
|
CALL METHOD mo_plugin->('SET_ITEM')
|
|
EXPORTING
|
|
iv_obj_type = is_item-obj_type
|
|
iv_obj_name = is_item-obj_name.
|
|
ELSE.
|
|
RAISE EXCEPTION TYPE cx_sy_create_object_error
|
|
EXPORTING
|
|
classname = 'LCL_OBJECTS_BRIDGE'.
|
|
ENDIF.
|
|
ENDMETHOD.
|
|
|
|
|
|
METHOD zif_abapgit_object~changed_by.
|
|
rv_user = c_user_unknown. " todo
|
|
ENDMETHOD.
|
|
|
|
|
|
METHOD zif_abapgit_object~delete.
|
|
DATA lx_plugin TYPE REF TO cx_static_check.
|
|
|
|
TRY.
|
|
CALL METHOD mo_plugin->('ZIF_ABAPGITP_PLUGIN~DELETE').
|
|
CATCH cx_static_check INTO lx_plugin.
|
|
zcx_abapgit_exception=>raise( lx_plugin->get_text( ) ).
|
|
ENDTRY.
|
|
|
|
ENDMETHOD.
|
|
|
|
|
|
METHOD zif_abapgit_object~deserialize.
|
|
|
|
DATA: lx_plugin TYPE REF TO cx_static_check.
|
|
|
|
TRY.
|
|
CALL METHOD mo_plugin->('WRAP_DESERIALIZE')
|
|
EXPORTING
|
|
iv_package = iv_package
|
|
io_xml = io_xml.
|
|
CATCH cx_static_check INTO lx_plugin.
|
|
zcx_abapgit_exception=>raise( lx_plugin->get_text( ) ).
|
|
ENDTRY.
|
|
ENDMETHOD.
|
|
|
|
|
|
METHOD zif_abapgit_object~exists.
|
|
|
|
CALL METHOD mo_plugin->('ZIF_ABAPGITP_PLUGIN~EXISTS')
|
|
RECEIVING
|
|
rv_bool = rv_bool.
|
|
|
|
ENDMETHOD.
|
|
|
|
|
|
METHOD zif_abapgit_object~get_comparator.
|
|
RETURN.
|
|
ENDMETHOD.
|
|
|
|
|
|
METHOD zif_abapgit_object~get_deserialize_order.
|
|
RETURN.
|
|
ENDMETHOD.
|
|
|
|
|
|
METHOD zif_abapgit_object~get_deserialize_steps.
|
|
|
|
DATA ls_meta TYPE ty_metadata.
|
|
|
|
CALL METHOD mo_plugin->('ZIF_ABAPGITP_PLUGIN~GET_METADATA')
|
|
RECEIVING
|
|
rs_metadata = ls_meta.
|
|
|
|
IF ls_meta-late_deser = abap_true.
|
|
APPEND zif_abapgit_object=>gc_step_id-late TO rt_steps.
|
|
ELSEIF ls_meta-ddic = abap_true.
|
|
APPEND zif_abapgit_object=>gc_step_id-ddic TO rt_steps.
|
|
ELSE.
|
|
APPEND zif_abapgit_object=>gc_step_id-abap TO rt_steps.
|
|
ENDIF.
|
|
|
|
ENDMETHOD.
|
|
|
|
|
|
METHOD zif_abapgit_object~get_metadata.
|
|
|
|
DATA ls_meta TYPE ty_metadata.
|
|
|
|
CALL METHOD mo_plugin->('ZIF_ABAPGITP_PLUGIN~GET_METADATA')
|
|
RECEIVING
|
|
rs_metadata = ls_meta.
|
|
|
|
MOVE-CORRESPONDING ls_meta TO rs_metadata.
|
|
|
|
ENDMETHOD.
|
|
|
|
|
|
METHOD zif_abapgit_object~is_active.
|
|
rv_active = abap_true.
|
|
ENDMETHOD.
|
|
|
|
|
|
METHOD zif_abapgit_object~is_locked.
|
|
|
|
rv_is_locked = abap_false.
|
|
|
|
ENDMETHOD.
|
|
|
|
|
|
METHOD zif_abapgit_object~jump.
|
|
|
|
CALL METHOD mo_plugin->('ZIF_ABAPGITP_PLUGIN~JUMP').
|
|
rv_exit = abap_true.
|
|
|
|
ENDMETHOD.
|
|
|
|
|
|
METHOD zif_abapgit_object~map_filename_to_object.
|
|
RETURN.
|
|
ENDMETHOD.
|
|
|
|
|
|
METHOD zif_abapgit_object~map_object_to_filename.
|
|
RETURN.
|
|
ENDMETHOD.
|
|
|
|
|
|
METHOD zif_abapgit_object~serialize.
|
|
|
|
CALL METHOD mo_plugin->('WRAP_SERIALIZE')
|
|
EXPORTING
|
|
io_xml = io_xml.
|
|
|
|
ENDMETHOD.
|
|
ENDCLASS.
|