mirror of
https://github.com/abapGit/abapGit.git
synced 2025-05-01 20:32:26 +08:00
f14ac831ba
* add global classes for objects * fix metadata * comment old code fix serializer class move missing interfaces * keep objects and bridge as local * fix syntax errors and remove SICF -> tadir dependency, instead tadir -> SICF * remove dependency TABL -> lcl_popups * fix indentation * remove old includes * fix parser errors * fix deserializing
300 lines
7.7 KiB
ABAP
300 lines
7.7 KiB
ABAP
CLASS zcl_abapgit_object_iamu DEFINITION PUBLIC INHERITING FROM zcl_abapgit_objects_super FINAL.
|
|
|
|
PUBLIC SECTION.
|
|
INTERFACES zif_abapgit_object.
|
|
ALIASES mo_files FOR zif_abapgit_object~mo_files.
|
|
|
|
PRIVATE SECTION.
|
|
TYPES: BEGIN OF ty_internet_appl_comp_binary,
|
|
attributes TYPE w3mimeattr,
|
|
source TYPE w3mimetabtype,
|
|
length TYPE i,
|
|
END OF ty_internet_appl_comp_binary.
|
|
|
|
DATA: mo_mime_api TYPE REF TO if_w3_api_mime.
|
|
|
|
METHODS:
|
|
load_mime_api
|
|
RAISING
|
|
zcx_abapgit_exception,
|
|
|
|
read
|
|
RETURNING
|
|
VALUE(rs_internet_appl_comp_binary) TYPE ty_internet_appl_comp_binary
|
|
RAISING
|
|
zcx_abapgit_exception,
|
|
|
|
save
|
|
IMPORTING
|
|
is_internet_appl_comp_binary TYPE ty_internet_appl_comp_binary
|
|
RAISING
|
|
zcx_abapgit_exception,
|
|
|
|
release_lock
|
|
RAISING
|
|
zcx_abapgit_exception.
|
|
|
|
ENDCLASS.
|
|
|
|
CLASS zcl_abapgit_object_iamu IMPLEMENTATION.
|
|
|
|
METHOD zif_abapgit_object~has_changed_since.
|
|
|
|
rv_changed = abap_true.
|
|
|
|
ENDMETHOD.
|
|
|
|
METHOD zif_abapgit_object~changed_by.
|
|
|
|
rv_user = c_user_unknown.
|
|
|
|
ENDMETHOD.
|
|
|
|
METHOD zif_abapgit_object~get_metadata.
|
|
|
|
rs_metadata = get_metadata( ).
|
|
|
|
ENDMETHOD.
|
|
|
|
METHOD zif_abapgit_object~serialize.
|
|
|
|
DATA: ls_internet_appl_comp_binary TYPE ty_internet_appl_comp_binary.
|
|
|
|
ls_internet_appl_comp_binary = read( ).
|
|
|
|
io_xml->add( iv_name = 'IAMU'
|
|
ig_data = ls_internet_appl_comp_binary ).
|
|
|
|
ENDMETHOD.
|
|
|
|
METHOD zif_abapgit_object~deserialize.
|
|
|
|
DATA: ls_internet_appl_comp_binary TYPE ty_internet_appl_comp_binary.
|
|
|
|
io_xml->read(
|
|
EXPORTING
|
|
iv_name = 'IAMU'
|
|
CHANGING
|
|
cg_data = ls_internet_appl_comp_binary ).
|
|
|
|
ls_internet_appl_comp_binary-attributes-devclass = iv_package.
|
|
|
|
save( ls_internet_appl_comp_binary ).
|
|
|
|
ENDMETHOD.
|
|
|
|
METHOD zif_abapgit_object~delete.
|
|
|
|
load_mime_api( ).
|
|
|
|
mo_mime_api->if_w3_api_object~set_changeable(
|
|
EXPORTING
|
|
p_changeable = abap_true
|
|
EXCEPTIONS
|
|
action_cancelled = 1
|
|
object_locked_by_other_user = 2
|
|
permission_failure = 3
|
|
object_already_changeable = 4
|
|
object_already_unlocked = 5
|
|
object_just_created = 6
|
|
object_deleted = 7
|
|
object_modified = 8
|
|
object_not_existing = 9
|
|
object_invalid = 10
|
|
error_occured = 11
|
|
OTHERS = 12 ).
|
|
|
|
IF sy-subrc <> 0.
|
|
zcx_abapgit_exception=>raise( |Error from if_w3_api_mime~set_changeable| ).
|
|
ENDIF.
|
|
|
|
mo_mime_api->if_w3_api_object~delete(
|
|
EXCEPTIONS
|
|
object_not_empty = 1
|
|
object_not_changeable = 2
|
|
object_invalid = 3
|
|
error_occured = 4
|
|
OTHERS = 5 ).
|
|
IF sy-subrc <> 0.
|
|
zcx_abapgit_exception=>raise( |Error from if_w3_api_mime~delete| ).
|
|
ENDIF.
|
|
|
|
mo_mime_api->if_w3_api_object~save(
|
|
EXCEPTIONS
|
|
object_invalid = 1
|
|
object_not_changeable = 2
|
|
action_cancelled = 3
|
|
permission_failure = 4
|
|
not_changed = 5
|
|
data_invalid = 6
|
|
error_occured = 7
|
|
OTHERS = 8 ).
|
|
|
|
IF sy-subrc <> 0.
|
|
zcx_abapgit_exception=>raise( |Error from if_w3_api_mime~save| ).
|
|
ENDIF.
|
|
|
|
ENDMETHOD.
|
|
|
|
METHOD zif_abapgit_object~exists.
|
|
|
|
DATA: ls_mime_name TYPE iacikeym.
|
|
|
|
ls_mime_name = ms_item-obj_name.
|
|
|
|
cl_w3_api_mime=>s_check_exist(
|
|
EXPORTING
|
|
p_mime_name = ls_mime_name
|
|
IMPORTING
|
|
p_exists = rv_bool ).
|
|
|
|
ENDMETHOD.
|
|
|
|
METHOD zif_abapgit_object~jump.
|
|
|
|
CALL FUNCTION 'RS_TOOL_ACCESS'
|
|
EXPORTING
|
|
operation = 'SHOW'
|
|
object_name = ms_item-obj_name
|
|
object_type = ms_item-obj_type.
|
|
|
|
ENDMETHOD.
|
|
|
|
METHOD zif_abapgit_object~compare_to_remote_version.
|
|
|
|
CREATE OBJECT ro_comparison_result TYPE zcl_abapgit_comparison_null.
|
|
|
|
ENDMETHOD.
|
|
|
|
METHOD load_mime_api.
|
|
|
|
DATA: ls_mime_name TYPE iacikeym.
|
|
|
|
ls_mime_name = ms_item-obj_name.
|
|
|
|
cl_w3_api_mime=>if_w3_api_mime~load(
|
|
EXPORTING
|
|
p_mime_name = ls_mime_name
|
|
IMPORTING
|
|
p_mime = mo_mime_api
|
|
EXCEPTIONS
|
|
object_not_existing = 1
|
|
permission_failure = 2
|
|
data_corrupt = 3
|
|
error_occured = 4
|
|
OTHERS = 6 ).
|
|
|
|
IF sy-subrc <> 0.
|
|
zcx_abapgit_exception=>raise( 'error from if_w3_api_mime~load' ).
|
|
ENDIF.
|
|
|
|
ENDMETHOD.
|
|
|
|
METHOD read.
|
|
|
|
load_mime_api( ).
|
|
|
|
mo_mime_api->get_attributes(
|
|
IMPORTING
|
|
p_attributes = rs_internet_appl_comp_binary-attributes
|
|
EXCEPTIONS
|
|
object_invalid = 1
|
|
mime_deleted = 2
|
|
error_occured = 3
|
|
OTHERS = 4 ).
|
|
|
|
IF sy-subrc <> 0.
|
|
zcx_abapgit_exception=>raise( |Error from if_w3_api_mime~get_attributes| ).
|
|
ENDIF.
|
|
|
|
CLEAR: rs_internet_appl_comp_binary-attributes-chname,
|
|
rs_internet_appl_comp_binary-attributes-tdate,
|
|
rs_internet_appl_comp_binary-attributes-ttime,
|
|
rs_internet_appl_comp_binary-attributes-devclass.
|
|
|
|
mo_mime_api->get_source(
|
|
IMPORTING
|
|
p_source = rs_internet_appl_comp_binary-source
|
|
p_datalength = rs_internet_appl_comp_binary-length
|
|
EXCEPTIONS
|
|
object_invalid = 1
|
|
mime_deleted = 2
|
|
error_occured = 3
|
|
OTHERS = 4 ).
|
|
|
|
IF sy-subrc <> 0.
|
|
zcx_abapgit_exception=>raise( |Error from if_w3_api_mime~get_source| ).
|
|
ENDIF.
|
|
|
|
ENDMETHOD.
|
|
|
|
METHOD save.
|
|
|
|
cl_w3_api_mime=>if_w3_api_mime~create_new(
|
|
EXPORTING
|
|
p_mime_data = is_internet_appl_comp_binary-attributes
|
|
p_mime_content = is_internet_appl_comp_binary-source
|
|
p_datalength = is_internet_appl_comp_binary-length
|
|
IMPORTING
|
|
p_mime = mo_mime_api
|
|
EXCEPTIONS
|
|
object_already_existing = 1
|
|
object_just_created = 2
|
|
not_authorized = 3
|
|
undefined_name = 4
|
|
author_not_existing = 5
|
|
action_cancelled = 6
|
|
error_occured = 7
|
|
OTHERS = 8 ).
|
|
|
|
IF sy-subrc <> 0.
|
|
zcx_abapgit_exception=>raise( |Error from if_w3_api_mime~create_ne| ).
|
|
ENDIF.
|
|
|
|
mo_mime_api->if_w3_api_object~save(
|
|
EXCEPTIONS
|
|
object_invalid = 1
|
|
object_not_changeable = 2
|
|
action_cancelled = 3
|
|
permission_failure = 4
|
|
not_changed = 5
|
|
data_invalid = 6
|
|
error_occured = 7
|
|
OTHERS = 8 ).
|
|
|
|
IF sy-subrc <> 0.
|
|
zcx_abapgit_exception=>raise( |Error from if_w3_api_mime~save| ).
|
|
ENDIF.
|
|
|
|
release_lock( ).
|
|
|
|
ENDMETHOD.
|
|
|
|
METHOD release_lock.
|
|
|
|
" As a side effect this method removes also existing locks
|
|
mo_mime_api->if_w3_api_object~set_changeable(
|
|
EXPORTING
|
|
p_changeable = abap_false
|
|
EXCEPTIONS
|
|
action_cancelled = 1
|
|
object_locked_by_other_user = 2
|
|
permission_failure = 3
|
|
object_already_changeable = 4
|
|
object_already_unlocked = 5
|
|
object_just_created = 6
|
|
object_deleted = 7
|
|
object_modified = 8
|
|
object_not_existing = 9
|
|
object_invalid = 10
|
|
error_occured = 11
|
|
OTHERS = 12 ).
|
|
|
|
IF sy-subrc <> 0.
|
|
zcx_abapgit_exception=>raise( |Error from if_w3_api_mime~set_changeable| ).
|
|
ENDIF.
|
|
|
|
ENDMETHOD.
|
|
|
|
ENDCLASS.
|