SAP/abapGit
1
0
Fork 0
mirror of https://github.com/abapGit/abapGit.git synced 2025-05-01 04:08:27 +08:00
Code Issues Actions 1 Packages Projects Releases Wiki Activity
20c1a3c610
abapGit/src/objects/zcl_abapgit_object_iasp.clas.abap
Marc Bernard 20c1a3c610
Refactor serializer constructor (#6701)
2023-12-18 17:16:00 -05:00

405 lines
9.7 KiB
ABAP
Raw Blame History

CLASS zcl_abapgit_object_iasp DEFINITION PUBLIC INHERITING FROM zcl_abapgit_objects_super FINAL.
PUBLIC SECTION.
INTERFACES zif_abapgit_object.
METHODS constructor
IMPORTING
!is_item TYPE zif_abapgit_definitions=>ty_item
!iv_language TYPE spras
!io_files TYPE REF TO zcl_abapgit_objects_files OPTIONAL
!io_i18n_params TYPE REF TO zcl_abapgit_i18n_params OPTIONAL
RAISING
zcx_abapgit_exception.
PROTECTED SECTION.
PRIVATE SECTION.
DATA:
mv_name TYPE itsappl.
METHODS:
read
EXPORTING es_attr TYPE w3servattr
et_parameters TYPE w3servpara_tabletype
RAISING zcx_abapgit_exception,
save
IMPORTING is_attr TYPE w3servattr
it_parameters TYPE w3servpara_tabletype
RAISING zcx_abapgit_exception,
w3_api_load
RETURNING VALUE(ri_service) TYPE REF TO if_w3_api_service
RAISING zcx_abapgit_exception,
w3_api_get_attributes
IMPORTING ii_service TYPE REF TO if_w3_api_service
RETURNING VALUE(rs_attributes) TYPE w3servattr,
w3_api_get_parameters
IMPORTING ii_service TYPE REF TO if_w3_api_service
RETURNING VALUE(rt_parameters) TYPE w3servpara_tabletype,
w3_api_create_new
IMPORTING is_attributes TYPE w3servattr
RETURNING VALUE(ri_service) TYPE REF TO if_w3_api_service
RAISING zcx_abapgit_exception,
w3_api_set_attributes
IMPORTING ii_service TYPE REF TO if_w3_api_service
is_attributes TYPE w3servattr
RAISING zcx_abapgit_exception,
w3_api_set_parameters
IMPORTING ii_service TYPE REF TO if_w3_api_service
it_parameters TYPE w3servpara_tabletype
RAISING zcx_abapgit_exception,
w3_api_save
IMPORTING ii_service TYPE REF TO if_w3_api_service
RAISING zcx_abapgit_exception,
w3_api_set_changeable
IMPORTING ii_service TYPE REF TO if_w3_api_service
iv_changeable TYPE abap_bool DEFAULT abap_true
RAISING zcx_abapgit_exception,
w3_api_delete
IMPORTING ii_service TYPE REF TO if_w3_api_service
RAISING zcx_abapgit_exception.
ENDCLASS.
CLASS zcl_abapgit_object_iasp IMPLEMENTATION.
METHOD constructor.
super->constructor(
is_item = is_item
iv_language = iv_language
io_files = io_files
io_i18n_params = io_i18n_params ).
mv_name = ms_item-obj_name.
ENDMETHOD.
METHOD read.
DATA: li_service TYPE REF TO if_w3_api_service.
li_service = w3_api_load( ).
es_attr = w3_api_get_attributes( li_service ).
CLEAR: es_attr-chname,
es_attr-tdate,
es_attr-ttime,
es_attr-devclass.
et_parameters = w3_api_get_parameters( li_service ).
ENDMETHOD.
METHOD save.
DATA: li_service TYPE REF TO if_w3_api_service.
li_service = w3_api_create_new( is_attr ).
w3_api_set_attributes(
ii_service = li_service
is_attributes = is_attr ).
w3_api_set_parameters(
ii_service = li_service
it_parameters = it_parameters ).
w3_api_save( li_service ).
" Release locks
w3_api_set_changeable(
ii_service = li_service
iv_changeable = abap_false ).
ENDMETHOD.
METHOD w3_api_create_new.
cl_w3_api_service=>if_w3_api_service~create_new(
EXPORTING
p_service_data = is_attributes
IMPORTING
p_service = ri_service
EXCEPTIONS
object_already_existing = 1
object_just_created = 2
not_authorized = 3
undefined_name = 4
author_not_existing = 5
action_cancelled = 6
error_occured = 7
invalid_parameter = 8
OTHERS = 9 ).
IF sy-subrc <> 0.
zcx_abapgit_exception=>raise( |error from if_w3_api_service~create_new. Subrc={ sy-subrc }| ).
ENDIF.
ENDMETHOD.
METHOD w3_api_delete.
ii_service->if_w3_api_object~delete(
EXCEPTIONS
object_not_empty = 1
object_not_changeable = 2
object_invalid = 3
error_occured = 4
OTHERS = 5 ).
IF sy-subrc <> 0.
zcx_abapgit_exception=>raise( |error from if_w3_api_object~delete. Subrc={ sy-subrc }| ).
ENDIF.
ENDMETHOD.
METHOD w3_api_get_attributes.
ii_service->get_attributes( IMPORTING p_attributes = rs_attributes ).
ENDMETHOD.
METHOD w3_api_get_parameters.
ii_service->get_parameters( IMPORTING p_parameters = rt_parameters ).
ENDMETHOD.
METHOD w3_api_load.
cl_w3_api_service=>if_w3_api_service~load(
EXPORTING
p_service_name = mv_name
IMPORTING
p_service = ri_service
EXCEPTIONS
object_not_existing = 1
permission_failure = 2
error_occured = 3
OTHERS = 4 ).
IF sy-subrc <> 0.
zcx_abapgit_exception=>raise( 'error from w3api_service~load' ).
ENDIF.
ENDMETHOD.
METHOD w3_api_save.
ii_service->if_w3_api_object~save(
EXCEPTIONS
object_invalid = 1
object_not_changeable = 2
action_cancelled = 3
permission_failure = 4
not_changed = 5
data_invalid = 6
error_occured = 7
OTHERS = 8 ).
IF sy-subrc <> 0.
zcx_abapgit_exception=>raise( |error from if_w3_api_object~save. Subrc={ sy-subrc }| ).
ENDIF.
ENDMETHOD.
METHOD w3_api_set_attributes.
ii_service->set_attributes(
EXPORTING
p_attributes = is_attributes
EXCEPTIONS
object_not_changeable = 1
object_deleted = 2
object_invalid = 3
author_not_existing = 4
authorize_failure = 5
error_occured = 6
OTHERS = 7 ).
IF sy-subrc <> 0.
zcx_abapgit_exception=>raise( |error from if_w3_api_service~set_attributes. Subrc={ sy-subrc }| ).
ENDIF.
ENDMETHOD.
METHOD w3_api_set_changeable.
ii_service->if_w3_api_object~set_changeable(
EXPORTING
p_changeable = iv_changeable
EXCEPTIONS
action_cancelled = 1
object_locked_by_other_user = 2
permission_failure = 3
object_already_changeable = 4
object_already_unlocked = 5
object_just_created = 6
object_deleted = 7
object_modified = 8
object_not_existing = 9
object_invalid = 10
error_occured = 11
OTHERS = 12 ).
IF sy-subrc <> 0.
zcx_abapgit_exception=>raise( |error from if_w3_api_object~set_changeable. Subrc={ sy-subrc }| ).
ENDIF.
ENDMETHOD.
METHOD w3_api_set_parameters.
ii_service->set_parameters(
EXPORTING
p_parameters = it_parameters
EXCEPTIONS
object_not_changeable = 1
object_deleted = 2
object_invalid = 3
authorize_failure = 4
invalid_parameter = 5
error_occured = 6
OTHERS = 7 ).
IF sy-subrc <> 0.
zcx_abapgit_exception=>raise( |error from if_w3_api_service~set_parameters. Subrc={ sy-subrc }| ).
ENDIF.
ENDMETHOD.
METHOD zif_abapgit_object~changed_by.
rv_user = c_user_unknown. " todo
ENDMETHOD.
METHOD zif_abapgit_object~delete.
DATA: li_service TYPE REF TO if_w3_api_service.
li_service = w3_api_load( ).
w3_api_set_changeable( li_service ).
w3_api_delete( li_service ).
w3_api_save( li_service ).
ENDMETHOD.
METHOD zif_abapgit_object~deserialize.
DATA: ls_attr TYPE w3servattr,
lt_parameters TYPE w3servpara_tabletype.
io_xml->read( EXPORTING iv_name = 'ATTR'
CHANGING cg_data = ls_attr ).
io_xml->read( EXPORTING iv_name = 'PARAMETERS'
CHANGING cg_data = lt_parameters ).
ls_attr-devclass = iv_package.
save( is_attr = ls_attr
it_parameters = lt_parameters ).
ENDMETHOD.
METHOD zif_abapgit_object~exists.
DATA: lx_error TYPE REF TO zcx_abapgit_exception.
TRY.
w3_api_load( ).
rv_bool = abap_true.
CATCH zcx_abapgit_exception INTO lx_error.
rv_bool = abap_false.
ENDTRY.
ENDMETHOD.
METHOD zif_abapgit_object~get_comparator.
RETURN.
ENDMETHOD.
METHOD zif_abapgit_object~get_deserialize_order.
RETURN.
ENDMETHOD.
METHOD zif_abapgit_object~get_deserialize_steps.
APPEND zif_abapgit_object=>gc_step_id-abap TO rt_steps.
ENDMETHOD.
METHOD zif_abapgit_object~get_metadata.
rs_metadata = get_metadata( ).
ENDMETHOD.
METHOD zif_abapgit_object~is_active.
rv_active = is_active( ).
ENDMETHOD.
METHOD zif_abapgit_object~is_locked.
rv_is_locked = abap_false.
ENDMETHOD.
METHOD zif_abapgit_object~jump.
" Covered by ZCL_ABAPGIT_OBJECTS=>JUMP
ENDMETHOD.
METHOD zif_abapgit_object~map_filename_to_object.
RETURN.
ENDMETHOD.
METHOD zif_abapgit_object~map_object_to_filename.
RETURN.
ENDMETHOD.
METHOD zif_abapgit_object~serialize.
DATA: ls_attr TYPE w3servattr,
lt_parameters TYPE w3servpara_tabletype.
IF zif_abapgit_object~exists( ) = abap_false.
RETURN.
ENDIF.
read( IMPORTING es_attr = ls_attr
et_parameters = lt_parameters ).
io_xml->add( iv_name = 'ATTR'
ig_data = ls_attr ).
io_xml->add( iv_name = 'PARAMETERS'
ig_data = lt_parameters ).
ENDMETHOD.
ENDCLASS.
Reference in New Issue View Git Blame Copy Permalink