mirror of
https://github.com/abapGit/abapGit.git
synced 2025-04-30 11:46:38 +08:00
298 lines
8.8 KiB
ABAP
298 lines
8.8 KiB
ABAP
CLASS zcl_abapgit_object_msag DEFINITION PUBLIC INHERITING FROM zcl_abapgit_objects_super FINAL.
|
|
|
|
PUBLIC SECTION.
|
|
INTERFACES zif_abapgit_object.
|
|
ALIASES mo_files FOR zif_abapgit_object~mo_files.
|
|
|
|
PRIVATE SECTION.
|
|
TYPES: BEGIN OF ty_t100_texts,
|
|
sprsl TYPE t100-sprsl,
|
|
msgnr TYPE t100-msgnr,
|
|
text TYPE t100-text,
|
|
END OF ty_t100_texts,
|
|
tt_t100_texts TYPE STANDARD TABLE OF ty_t100_texts.
|
|
|
|
METHODS:
|
|
serialize_texts
|
|
IMPORTING io_xml TYPE REF TO zcl_abapgit_xml_output
|
|
RAISING zcx_abapgit_exception,
|
|
deserialize_texts
|
|
IMPORTING io_xml TYPE REF TO zcl_abapgit_xml_input
|
|
RAISING zcx_abapgit_exception.
|
|
|
|
|
|
ENDCLASS.
|
|
|
|
CLASS zcl_abapgit_object_msag IMPLEMENTATION.
|
|
|
|
METHOD zif_abapgit_object~has_changed_since.
|
|
rv_changed = abap_true.
|
|
ENDMETHOD. "zif_abapgit_object~has_changed_since
|
|
|
|
METHOD zif_abapgit_object~changed_by.
|
|
|
|
SELECT SINGLE lastuser FROM t100a INTO rv_user
|
|
WHERE arbgb = ms_item-obj_name. "#EC CI_GENBUFF
|
|
IF sy-subrc <> 0 OR rv_user = ''.
|
|
rv_user = c_user_unknown.
|
|
ENDIF.
|
|
|
|
ENDMETHOD.
|
|
|
|
METHOD zif_abapgit_object~get_metadata.
|
|
rs_metadata = get_metadata( ).
|
|
ENDMETHOD. "zif_abapgit_object~get_metadata
|
|
|
|
METHOD zif_abapgit_object~exists.
|
|
|
|
DATA: lv_arbgb TYPE t100a-arbgb.
|
|
|
|
|
|
SELECT SINGLE arbgb FROM t100a INTO lv_arbgb
|
|
WHERE arbgb = ms_item-obj_name. "#EC CI_GENBUFF
|
|
rv_bool = boolc( sy-subrc = 0 ).
|
|
|
|
ENDMETHOD. "zif_abapgit_object~exists
|
|
|
|
METHOD zif_abapgit_object~jump.
|
|
|
|
CALL FUNCTION 'RS_TOOL_ACCESS'
|
|
EXPORTING
|
|
operation = 'SHOW'
|
|
object_name = ms_item-obj_name
|
|
object_type = 'MSAG'
|
|
in_new_window = abap_true.
|
|
|
|
ENDMETHOD. "jump
|
|
|
|
METHOD zif_abapgit_object~delete.
|
|
|
|
* parameter SUPPRESS_DIALOG doesnt exist in all versions
|
|
CALL FUNCTION 'RS_DELETE_MESSAGE_ID'
|
|
EXPORTING
|
|
nachrichtenklasse = ms_item-obj_name
|
|
EXCEPTIONS
|
|
not_executed = 1
|
|
not_found = 2
|
|
no_permission = 3
|
|
OTHERS = 4.
|
|
IF sy-subrc <> 0.
|
|
zcx_abapgit_exception=>raise( 'Error from RS_DELETE_MESSAGE_ID' ).
|
|
ENDIF.
|
|
|
|
ENDMETHOD. "delete
|
|
|
|
METHOD zif_abapgit_object~deserialize.
|
|
* fm RPY_MESSAGE_ID_INSERT almost works, but not in older versions
|
|
|
|
DATA: ls_t100a TYPE t100a,
|
|
ls_t100t TYPE t100t,
|
|
ls_t100u TYPE t100u,
|
|
lt_t100 TYPE TABLE OF t100,
|
|
lt_before TYPE TABLE OF t100u.
|
|
|
|
FIELD-SYMBOLS: <ls_t100> LIKE LINE OF lt_t100.
|
|
|
|
|
|
io_xml->read( EXPORTING iv_name = 'T100A'
|
|
CHANGING cg_data = ls_t100a ).
|
|
io_xml->read( EXPORTING iv_name = 'T100'
|
|
CHANGING cg_data = lt_t100 ).
|
|
|
|
CALL FUNCTION 'RS_CORR_INSERT'
|
|
EXPORTING
|
|
global_lock = abap_true
|
|
devclass = iv_package
|
|
object = ls_t100a-arbgb
|
|
object_class = 'T100'
|
|
mode = 'INSERT'
|
|
EXCEPTIONS
|
|
cancelled = 01
|
|
permission_failure = 02
|
|
unknown_objectclass = 03.
|
|
IF sy-subrc <> 0.
|
|
zcx_abapgit_exception=>raise( 'Error from RS_CORR_INSERT' ).
|
|
ENDIF.
|
|
|
|
SELECT * FROM t100u INTO TABLE lt_before
|
|
WHERE arbgb = ls_t100a-arbgb ORDER BY msgnr. "#EC CI_GENBUFF "#EC CI_BYPASS
|
|
|
|
LOOP AT lt_t100 ASSIGNING <ls_t100>.
|
|
DELETE lt_before WHERE msgnr = <ls_t100>-msgnr.
|
|
MODIFY t100 FROM <ls_t100>. "#EC CI_SUBRC
|
|
IF sy-subrc <> 0.
|
|
zcx_abapgit_exception=>raise( 'MSAG: Table T100 modify failed' ).
|
|
ENDIF.
|
|
CLEAR ls_t100u.
|
|
MOVE-CORRESPONDING <ls_t100> TO ls_t100u ##enh_ok.
|
|
ls_t100u-name = sy-uname.
|
|
ls_t100u-datum = sy-datum.
|
|
ls_t100u-selfdef = '3'.
|
|
MODIFY t100u FROM ls_t100u. "#EC CI_SUBRC
|
|
IF sy-subrc <> 0.
|
|
zcx_abapgit_exception=>raise( 'MSAG: Table T100U modify failed' ).
|
|
ENDIF.
|
|
ENDLOOP.
|
|
|
|
ls_t100a-masterlang = mv_language.
|
|
ls_t100a-lastuser = sy-uname.
|
|
ls_t100a-respuser = sy-uname.
|
|
ls_t100a-ldate = sy-datum.
|
|
ls_t100a-ltime = sy-uzeit.
|
|
MODIFY t100a FROM ls_t100a. "#EC CI_SUBRC
|
|
IF sy-subrc <> 0.
|
|
zcx_abapgit_exception=>raise( 'MSAG: Table T100A modify failed' ).
|
|
ENDIF.
|
|
|
|
ls_t100t-sprsl = mv_language.
|
|
ls_t100t-arbgb = ls_t100a-arbgb.
|
|
ls_t100t-stext = ls_t100a-stext.
|
|
MODIFY t100t FROM ls_t100t. "#EC CI_SUBRC
|
|
IF sy-subrc <> 0.
|
|
zcx_abapgit_exception=>raise( 'MSAG: Table T100T modify failed' ).
|
|
ENDIF.
|
|
|
|
LOOP AT lt_before INTO ls_t100u.
|
|
DELETE FROM t100 WHERE arbgb = ls_t100u-arbgb
|
|
AND msgnr = ls_t100u-msgnr. "#EC CI_SUBRC
|
|
|
|
DELETE FROM t100u WHERE arbgb = ls_t100u-arbgb
|
|
AND msgnr = ls_t100u-msgnr. "#EC CI_SUBRC
|
|
ENDLOOP.
|
|
|
|
deserialize_texts( io_xml = io_xml ).
|
|
|
|
ENDMETHOD. "deserialize
|
|
|
|
METHOD zif_abapgit_object~serialize.
|
|
|
|
DATA: lv_msg_id TYPE rglif-message_id,
|
|
ls_inf TYPE t100a,
|
|
lt_source TYPE TABLE OF t100.
|
|
|
|
|
|
lv_msg_id = ms_item-obj_name.
|
|
|
|
SELECT SINGLE * FROM t100a INTO ls_inf
|
|
WHERE arbgb = lv_msg_id. "#EC CI_GENBUFF
|
|
IF sy-subrc <> 0.
|
|
RETURN.
|
|
ENDIF.
|
|
CLEAR ls_inf-respuser.
|
|
|
|
SELECT * FROM t100 INTO TABLE lt_source
|
|
WHERE sprsl = mv_language
|
|
AND arbgb = lv_msg_id
|
|
ORDER BY PRIMARY KEY. "#EC CI_SUBRC "#EC CI_GENBUFF
|
|
|
|
CLEAR: ls_inf-lastuser,
|
|
ls_inf-ldate,
|
|
ls_inf-ltime.
|
|
|
|
io_xml->add( iv_name = 'T100A'
|
|
ig_data = ls_inf ).
|
|
io_xml->add( ig_data = lt_source
|
|
iv_name = 'T100' ).
|
|
|
|
serialize_texts( io_xml ).
|
|
|
|
ENDMETHOD. "serialize
|
|
|
|
METHOD serialize_texts.
|
|
|
|
DATA: lv_msg_id TYPE rglif-message_id,
|
|
lt_t100_texts TYPE tt_t100_texts,
|
|
lt_t100t TYPE TABLE OF t100t,
|
|
lt_i18n_langs TYPE TABLE OF langu.
|
|
|
|
lv_msg_id = ms_item-obj_name.
|
|
|
|
" Collect additional languages
|
|
" Skip master lang - it has been already serialized
|
|
SELECT DISTINCT sprsl AS langu INTO TABLE lt_i18n_langs
|
|
FROM t100t
|
|
WHERE arbgb = lv_msg_id
|
|
AND sprsl <> mv_language. "#EC CI_BYPASS "#EC CI_GENBUFF.
|
|
|
|
SORT lt_i18n_langs ASCENDING.
|
|
|
|
IF lines( lt_i18n_langs ) > 0.
|
|
|
|
SELECT * FROM t100t INTO CORRESPONDING FIELDS OF TABLE lt_t100t
|
|
WHERE sprsl <> mv_language
|
|
AND arbgb = lv_msg_id. "#EC CI_GENBUFF
|
|
|
|
SELECT * FROM t100 INTO CORRESPONDING FIELDS OF TABLE lt_t100_texts
|
|
FOR ALL ENTRIES IN lt_i18n_langs
|
|
WHERE sprsl = lt_i18n_langs-table_line
|
|
AND arbgb = lv_msg_id
|
|
ORDER BY PRIMARY KEY. "#EC CI_SUBRC "#EC CI_GENBUFF
|
|
|
|
SORT lt_t100t BY sprsl ASCENDING.
|
|
SORT lt_t100_texts BY sprsl msgnr ASCENDING.
|
|
|
|
io_xml->add( iv_name = 'I18N_LANGS'
|
|
ig_data = lt_i18n_langs ).
|
|
|
|
io_xml->add( iv_name = 'T100T'
|
|
ig_data = lt_t100t ).
|
|
|
|
io_xml->add( iv_name = 'T100_TEXTS'
|
|
ig_data = lt_t100_texts ).
|
|
|
|
ENDIF.
|
|
|
|
ENDMETHOD.
|
|
|
|
METHOD deserialize_texts.
|
|
|
|
DATA: lv_msg_id TYPE rglif-message_id,
|
|
ls_t100 TYPE t100,
|
|
lt_t100t TYPE TABLE OF t100t,
|
|
lt_t100_texts TYPE tt_t100_texts,
|
|
lt_t100u TYPE TABLE OF t100u.
|
|
|
|
FIELD-SYMBOLS: <ls_t100_text> TYPE ty_t100_texts.
|
|
|
|
|
|
lv_msg_id = ms_item-obj_name.
|
|
|
|
SELECT * FROM t100u INTO TABLE lt_t100u
|
|
WHERE arbgb = lv_msg_id ORDER BY PRIMARY KEY. "#EC CI_GENBUFF
|
|
|
|
io_xml->read( EXPORTING iv_name = 'T100_TEXTS'
|
|
CHANGING cg_data = lt_t100_texts ).
|
|
|
|
io_xml->read( EXPORTING iv_name = 'T100T'
|
|
CHANGING cg_data = lt_t100t ).
|
|
|
|
MODIFY t100t FROM TABLE lt_t100t. "#EC CI_SUBRC
|
|
|
|
LOOP AT lt_t100_texts ASSIGNING <ls_t100_text>.
|
|
"check if message exists
|
|
READ TABLE lt_t100u TRANSPORTING NO FIELDS
|
|
WITH KEY arbgb = lv_msg_id msgnr = <ls_t100_text>-msgnr BINARY SEARCH.
|
|
CHECK sy-subrc = 0. "if original message doesn't exist no translations added
|
|
|
|
MOVE-CORRESPONDING <ls_t100_text> TO ls_t100.
|
|
ls_t100-arbgb = lv_msg_id.
|
|
MODIFY t100 FROM ls_t100. "#EC CI_SUBRC
|
|
IF sy-subrc <> 0.
|
|
zcx_abapgit_exception=>raise( 'MSAG: Table T100 modify failed' ).
|
|
ENDIF.
|
|
ENDLOOP.
|
|
|
|
ENDMETHOD.
|
|
|
|
METHOD zif_abapgit_object~compare_to_remote_version.
|
|
CREATE OBJECT ro_comparison_result TYPE zcl_abapgit_comparison_null.
|
|
ENDMETHOD.
|
|
|
|
METHOD zif_abapgit_object~is_locked.
|
|
|
|
rv_is_locked = abap_false.
|
|
|
|
ENDMETHOD.
|
|
|
|
ENDCLASS. "zcl_abapgit_object_msag IMPLEMENTATION
|