mirror of
https://github.com/abapGit/abapGit.git
synced 2025-05-02 21:08:01 +08:00
f14ac831ba
* add global classes for objects * fix metadata * comment old code fix serializer class move missing interfaces * keep objects and bridge as local * fix syntax errors and remove SICF -> tadir dependency, instead tadir -> SICF * remove dependency TABL -> lcl_popups * fix indentation * remove old includes * fix parser errors * fix deserializing
115 lines
2.9 KiB
ABAP
115 lines
2.9 KiB
ABAP
CLASS zcl_abapgit_object_susc DEFINITION PUBLIC INHERITING FROM zcl_abapgit_objects_super FINAL.
|
|
|
|
PUBLIC SECTION.
|
|
INTERFACES zif_abapgit_object.
|
|
ALIASES mo_files FOR zif_abapgit_object~mo_files.
|
|
|
|
ENDCLASS.
|
|
|
|
CLASS zcl_abapgit_object_susc IMPLEMENTATION.
|
|
|
|
METHOD zif_abapgit_object~has_changed_since.
|
|
rv_changed = abap_true.
|
|
ENDMETHOD. "zif_abapgit_object~has_changed_since
|
|
|
|
METHOD zif_abapgit_object~changed_by.
|
|
rv_user = c_user_unknown. " todo
|
|
ENDMETHOD.
|
|
|
|
METHOD zif_abapgit_object~get_metadata.
|
|
rs_metadata = get_metadata( ).
|
|
ENDMETHOD. "zif_abapgit_object~get_metadata
|
|
|
|
METHOD zif_abapgit_object~exists.
|
|
|
|
DATA: lv_oclss TYPE tobc-oclss.
|
|
|
|
|
|
SELECT SINGLE oclss FROM tobc INTO lv_oclss
|
|
WHERE oclss = ms_item-obj_name.
|
|
rv_bool = boolc( sy-subrc = 0 ).
|
|
|
|
ENDMETHOD. "zif_abapgit_object~exists
|
|
|
|
METHOD zif_abapgit_object~serialize.
|
|
|
|
DATA: ls_tobc TYPE tobc,
|
|
ls_tobct TYPE tobct.
|
|
|
|
|
|
SELECT SINGLE * FROM tobc INTO ls_tobc
|
|
WHERE oclss = ms_item-obj_name.
|
|
IF sy-subrc <> 0.
|
|
RETURN.
|
|
ENDIF.
|
|
|
|
SELECT SINGLE * FROM tobct INTO ls_tobct
|
|
WHERE oclss = ms_item-obj_name
|
|
AND langu = mv_language.
|
|
|
|
io_xml->add( iv_name = 'TOBC'
|
|
ig_data = ls_tobc ).
|
|
io_xml->add( iv_name = 'TOBCT'
|
|
ig_data = ls_tobct ).
|
|
|
|
ENDMETHOD. "serialize
|
|
|
|
METHOD zif_abapgit_object~deserialize.
|
|
* see function group SUSA
|
|
|
|
DATA: ls_tobc TYPE tobc,
|
|
lv_objectname TYPE e071-obj_name,
|
|
ls_tobct TYPE tobct.
|
|
|
|
|
|
io_xml->read( EXPORTING iv_name = 'TOBC'
|
|
CHANGING cg_data = ls_tobc ).
|
|
io_xml->read( EXPORTING iv_name = 'TOBCT'
|
|
CHANGING cg_data = ls_tobct ).
|
|
|
|
tadir_insert( iv_package ).
|
|
|
|
lv_objectname = ms_item-obj_name.
|
|
CALL FUNCTION 'SUSR_COMMEDITCHECK'
|
|
EXPORTING
|
|
objectname = lv_objectname
|
|
transobjecttype = 'C'.
|
|
|
|
INSERT tobc FROM ls_tobc. "#EC CI_SUBRC
|
|
* ignore sy-subrc as all fields are key fields
|
|
|
|
MODIFY tobct FROM ls_tobct. "#EC CI_SUBRC
|
|
ASSERT sy-subrc = 0.
|
|
|
|
ENDMETHOD. "deserialize
|
|
|
|
METHOD zif_abapgit_object~delete.
|
|
|
|
DATA: lv_objclass TYPE tobc-oclss.
|
|
|
|
|
|
lv_objclass = ms_item-obj_name.
|
|
CALL FUNCTION 'SUSR_DELETE_OBJECT_CLASS'
|
|
EXPORTING
|
|
objclass = lv_objclass.
|
|
|
|
ENDMETHOD. "delete
|
|
|
|
METHOD zif_abapgit_object~jump.
|
|
|
|
DATA: lv_objclass TYPE tobc-oclss.
|
|
|
|
|
|
lv_objclass = ms_item-obj_name.
|
|
CALL FUNCTION 'SUSR_SHOW_OBJECT_CLASS'
|
|
EXPORTING
|
|
objclass = lv_objclass.
|
|
|
|
ENDMETHOD. "jump
|
|
|
|
METHOD zif_abapgit_object~compare_to_remote_version.
|
|
CREATE OBJECT ro_comparison_result TYPE zcl_abapgit_comparison_null.
|
|
ENDMETHOD.
|
|
|
|
ENDCLASS. "zcl_abapgit_object_susc IMPLEMENTATION
|