mirror of
https://github.com/abapGit/abapGit.git
synced 2025-05-07 07:42:08 +08:00
73576ee60e
* Improve error messages Pass T100 messages to UI/log * T100 errors * APACK * OO * DEVC * DRUL * DTDC * SRVB * OBJS * Program Co-authored-by: Lars Hvam <larshp@hotmail.com>
208 lines
4.3 KiB
ABAP
208 lines
4.3 KiB
ABAP
CLASS zcl_abapgit_object_acid DEFINITION PUBLIC INHERITING FROM zcl_abapgit_objects_super FINAL.
|
|
|
|
PUBLIC SECTION.
|
|
INTERFACES zif_abapgit_object.
|
|
ALIASES mo_files FOR zif_abapgit_object~mo_files.
|
|
|
|
PROTECTED SECTION.
|
|
PRIVATE SECTION.
|
|
METHODS: create_object
|
|
RETURNING VALUE(ro_aab) TYPE REF TO cl_aab_id
|
|
RAISING zcx_abapgit_exception.
|
|
|
|
ENDCLASS.
|
|
|
|
|
|
|
|
CLASS zcl_abapgit_object_acid IMPLEMENTATION.
|
|
|
|
|
|
METHOD create_object.
|
|
|
|
DATA: lv_name TYPE aab_id_name.
|
|
|
|
|
|
lv_name = ms_item-obj_name.
|
|
|
|
CREATE OBJECT ro_aab
|
|
EXPORTING
|
|
im_name = lv_name
|
|
EXCEPTIONS
|
|
name_not_allowed = 1
|
|
OTHERS = 2.
|
|
IF sy-subrc <> 0.
|
|
zcx_abapgit_exception=>raise_t100( ).
|
|
ENDIF.
|
|
|
|
ENDMETHOD.
|
|
|
|
|
|
METHOD zif_abapgit_object~changed_by.
|
|
* looks like "changed by user" is not stored in the database
|
|
rv_user = c_user_unknown.
|
|
ENDMETHOD.
|
|
|
|
|
|
METHOD zif_abapgit_object~delete.
|
|
|
|
DATA: lo_aab TYPE REF TO cl_aab_id.
|
|
|
|
|
|
lo_aab = create_object( ).
|
|
lo_aab->enqueue(
|
|
EXCEPTIONS
|
|
foreign_lock = 1
|
|
system_error = 2
|
|
cts_error = 3
|
|
OTHERS = 4 ).
|
|
IF sy-subrc <> 0.
|
|
zcx_abapgit_exception=>raise_t100( ).
|
|
ENDIF.
|
|
lo_aab->delete(
|
|
EXCEPTIONS
|
|
prop_error = 1
|
|
propt_error = 2
|
|
act_error = 3
|
|
cts_error = 4
|
|
cts_devclass = 5
|
|
id_not_found = 6
|
|
no_authorization = 7
|
|
id_still_used = 8
|
|
where_used_error = 9
|
|
OTHERS = 10 ).
|
|
IF sy-subrc <> 0.
|
|
zcx_abapgit_exception=>raise_t100( ).
|
|
ENDIF.
|
|
lo_aab->dequeue( ).
|
|
|
|
ENDMETHOD.
|
|
|
|
|
|
METHOD zif_abapgit_object~deserialize.
|
|
|
|
DATA: lv_description TYPE aab_id_descript,
|
|
lo_aab TYPE REF TO cl_aab_id.
|
|
|
|
|
|
io_xml->read( EXPORTING iv_name = 'DESCRIPTION'
|
|
CHANGING cg_data = lv_description ).
|
|
|
|
lo_aab = create_object( ).
|
|
|
|
lo_aab->enqueue(
|
|
EXCEPTIONS
|
|
foreign_lock = 1
|
|
system_error = 2
|
|
cts_error = 3
|
|
OTHERS = 4 ).
|
|
IF sy-subrc <> 0.
|
|
zcx_abapgit_exception=>raise_t100( ).
|
|
ENDIF.
|
|
|
|
lo_aab->set_descript(
|
|
EXPORTING
|
|
im_descript = lv_description
|
|
EXCEPTIONS
|
|
no_authorization = 1
|
|
OTHERS = 2 ).
|
|
IF sy-subrc <> 0.
|
|
zcx_abapgit_exception=>raise_t100( ).
|
|
ENDIF.
|
|
|
|
tadir_insert( iv_package ).
|
|
|
|
lo_aab->save(
|
|
EXCEPTIONS
|
|
no_descript_specified = 1
|
|
no_changes_found = 2
|
|
prop_error = 3
|
|
propt_error = 4
|
|
act_error = 5
|
|
cts_error = 6
|
|
sync_attributes_error = 7
|
|
action_canceled = 8
|
|
OTHERS = 9 ).
|
|
IF sy-subrc >= 3.
|
|
zcx_abapgit_exception=>raise_t100( ).
|
|
ENDIF.
|
|
|
|
lo_aab->dequeue( ).
|
|
|
|
ENDMETHOD.
|
|
|
|
|
|
METHOD zif_abapgit_object~exists.
|
|
|
|
DATA: lv_state TYPE abap_bool,
|
|
lo_aab TYPE REF TO cl_aab_id.
|
|
|
|
|
|
lo_aab = create_object( ).
|
|
|
|
lo_aab->get_state( IMPORTING ex_state = lv_state ).
|
|
rv_bool = boolc( lv_state = abap_true ).
|
|
|
|
ENDMETHOD.
|
|
|
|
|
|
METHOD zif_abapgit_object~get_comparator.
|
|
RETURN.
|
|
ENDMETHOD.
|
|
|
|
|
|
METHOD zif_abapgit_object~get_deserialize_steps.
|
|
APPEND zif_abapgit_object=>gc_step_id-abap TO rt_steps.
|
|
ENDMETHOD.
|
|
|
|
|
|
METHOD zif_abapgit_object~get_metadata.
|
|
rs_metadata = get_metadata( ).
|
|
ENDMETHOD.
|
|
|
|
|
|
METHOD zif_abapgit_object~is_active.
|
|
rv_active = is_active( ).
|
|
ENDMETHOD.
|
|
|
|
|
|
METHOD zif_abapgit_object~is_locked.
|
|
|
|
rv_is_locked = abap_false.
|
|
|
|
ENDMETHOD.
|
|
|
|
|
|
METHOD zif_abapgit_object~jump.
|
|
|
|
CALL FUNCTION 'RS_TOOL_ACCESS'
|
|
EXPORTING
|
|
operation = 'SHOW'
|
|
object_name = ms_item-obj_name
|
|
object_type = 'ACID'
|
|
in_new_window = abap_true.
|
|
|
|
ENDMETHOD.
|
|
|
|
|
|
METHOD zif_abapgit_object~serialize.
|
|
|
|
DATA: lo_aab TYPE REF TO cl_aab_id,
|
|
lv_description TYPE aab_id_descript.
|
|
|
|
|
|
IF zif_abapgit_object~exists( ) = abap_false.
|
|
RETURN.
|
|
ENDIF.
|
|
|
|
lo_aab = create_object( ).
|
|
|
|
lo_aab->get_descript(
|
|
IMPORTING ex_descript = lv_description
|
|
EXCEPTIONS no_description_found = 1 ).
|
|
|
|
io_xml->add( iv_name = 'DESCRIPTION'
|
|
ig_data = lv_description ).
|
|
|
|
ENDMETHOD.
|
|
ENDCLASS.
|