mirror of
https://github.com/abapGit/abapGit.git
synced 2025-05-02 04:36:49 +08:00
7bbaf069e2
* File format update - changed object handler I removed the following fields: CLAS VSEOCLASS-VERSION INTF VSEOINTERF-VERSION PROG PROGDIR-STATE DCLS AS4LOCAL ABAP_LANGUAGE_VERSION (if exists) DDLS ABAP_LANGUAGE_VERSION (if exists) DDLX VERSION RESPONSIBLE MASTER_SYSTEM MSAG DOKIL-DOKSTATE ENQU DD25V-AS4LOCAL DD25V-AS4VERS * fix syntax error * also clear PROG VARCL * update XML files
242 lines
6.0 KiB
ABAP
242 lines
6.0 KiB
ABAP
CLASS zcl_abapgit_object_dcls DEFINITION PUBLIC INHERITING FROM zcl_abapgit_objects_super FINAL.
|
|
|
|
PUBLIC SECTION.
|
|
INTERFACES zif_abapgit_object.
|
|
ALIASES mo_files FOR zif_abapgit_object~mo_files.
|
|
|
|
PROTECTED SECTION.
|
|
PRIVATE SECTION.
|
|
ENDCLASS.
|
|
|
|
|
|
|
|
CLASS ZCL_ABAPGIT_OBJECT_DCLS IMPLEMENTATION.
|
|
|
|
|
|
METHOD zif_abapgit_object~changed_by.
|
|
rv_user = c_user_unknown.
|
|
ENDMETHOD.
|
|
|
|
|
|
METHOD zif_abapgit_object~delete.
|
|
|
|
DATA: lo_dcl TYPE REF TO object,
|
|
lx_error TYPE REF TO cx_root.
|
|
|
|
TRY.
|
|
CALL METHOD ('CL_ACM_DCL_HANDLER_FACTORY')=>('CREATE')
|
|
RECEIVING
|
|
ro_handler = lo_dcl.
|
|
|
|
CALL METHOD lo_dcl->('DELETE')
|
|
EXPORTING
|
|
iv_dclname = ms_item-obj_name.
|
|
|
|
CATCH cx_root INTO lx_error.
|
|
zcx_abapgit_exception=>raise( iv_text = lx_error->get_text( )
|
|
ix_previous = lx_error ).
|
|
ENDTRY.
|
|
|
|
ENDMETHOD.
|
|
|
|
|
|
METHOD zif_abapgit_object~deserialize.
|
|
|
|
DATA: lr_data TYPE REF TO data,
|
|
lo_dcl TYPE REF TO object,
|
|
lx_error TYPE REF TO cx_root.
|
|
|
|
FIELD-SYMBOLS: <lg_data> TYPE any,
|
|
<lg_field> TYPE any.
|
|
|
|
|
|
CREATE DATA lr_data TYPE ('ACM_S_DCLSRC').
|
|
ASSIGN lr_data->* TO <lg_data>.
|
|
|
|
io_xml->read(
|
|
EXPORTING
|
|
iv_name = 'DCLS'
|
|
CHANGING
|
|
cg_data = <lg_data> ).
|
|
|
|
ASSIGN COMPONENT 'SOURCE' OF STRUCTURE <lg_data> TO <lg_field>.
|
|
ASSERT sy-subrc = 0.
|
|
<lg_field> = mo_files->read_string( 'asdcls' ).
|
|
|
|
TRY.
|
|
tadir_insert( iv_package ).
|
|
|
|
CALL METHOD ('CL_ACM_DCL_HANDLER_FACTORY')=>('CREATE')
|
|
RECEIVING
|
|
ro_handler = lo_dcl.
|
|
|
|
CALL METHOD lo_dcl->('SAVE')
|
|
EXPORTING
|
|
iv_dclname = ms_item-obj_name
|
|
iv_put_state = 'I'
|
|
is_dclsrc = <lg_data>
|
|
iv_devclass = iv_package
|
|
iv_access_mode = 'INSERT'.
|
|
|
|
CATCH cx_root INTO lx_error.
|
|
zcx_abapgit_exception=>raise( iv_text = lx_error->get_text( )
|
|
ix_previous = lx_error ).
|
|
ENDTRY.
|
|
|
|
zcl_abapgit_objects_activation=>add_item( ms_item ).
|
|
|
|
ENDMETHOD.
|
|
|
|
|
|
METHOD zif_abapgit_object~exists.
|
|
|
|
DATA: lo_dcl TYPE REF TO object,
|
|
lx_error TYPE REF TO cx_root.
|
|
|
|
TRY.
|
|
CALL METHOD ('CL_ACM_DCL_HANDLER_FACTORY')=>('CREATE')
|
|
RECEIVING
|
|
ro_handler = lo_dcl.
|
|
|
|
CALL METHOD lo_dcl->('CHECK_EXISTENCE')
|
|
EXPORTING
|
|
iv_objectname = ms_item-obj_name
|
|
RECEIVING
|
|
rv_exists = rv_bool.
|
|
|
|
CATCH cx_root INTO lx_error.
|
|
zcx_abapgit_exception=>raise( iv_text = lx_error->get_text( )
|
|
ix_previous = lx_error ).
|
|
ENDTRY.
|
|
|
|
ENDMETHOD.
|
|
|
|
|
|
METHOD zif_abapgit_object~get_comparator.
|
|
RETURN.
|
|
ENDMETHOD.
|
|
|
|
|
|
METHOD zif_abapgit_object~get_deserialize_steps.
|
|
|
|
DATA: ls_meta TYPE zif_abapgit_definitions=>ty_metadata.
|
|
|
|
ls_meta = zif_abapgit_object~get_metadata( ).
|
|
|
|
IF ls_meta-late_deser = abap_true.
|
|
APPEND zif_abapgit_object=>gc_step_id-late TO rt_steps.
|
|
ELSEIF ls_meta-ddic = abap_true.
|
|
APPEND zif_abapgit_object=>gc_step_id-ddic TO rt_steps.
|
|
ELSE.
|
|
APPEND zif_abapgit_object=>gc_step_id-abap TO rt_steps.
|
|
ENDIF.
|
|
|
|
ENDMETHOD.
|
|
|
|
|
|
METHOD zif_abapgit_object~get_metadata.
|
|
rs_metadata = get_metadata( ).
|
|
|
|
rs_metadata-delete_tadir = abap_true.
|
|
rs_metadata-late_deser = abap_true.
|
|
ENDMETHOD.
|
|
|
|
|
|
METHOD zif_abapgit_object~is_active.
|
|
rv_active = is_active( ).
|
|
ENDMETHOD.
|
|
|
|
|
|
METHOD zif_abapgit_object~is_locked.
|
|
|
|
rv_is_locked = exists_a_lock_entry_for( iv_lock_object = 'E_ACMDCLSRC'
|
|
iv_argument = |{ ms_item-obj_name }| ).
|
|
|
|
ENDMETHOD.
|
|
|
|
|
|
METHOD zif_abapgit_object~jump.
|
|
|
|
TRY.
|
|
|
|
jump_adt( iv_obj_name = ms_item-obj_name
|
|
iv_obj_type = ms_item-obj_type ).
|
|
|
|
CATCH zcx_abapgit_exception.
|
|
zcx_abapgit_exception=>raise( 'DCLS Jump Error' ).
|
|
ENDTRY.
|
|
|
|
ENDMETHOD.
|
|
|
|
|
|
METHOD zif_abapgit_object~serialize.
|
|
|
|
DATA: lr_data TYPE REF TO data,
|
|
lo_dcl TYPE REF TO object,
|
|
lx_error TYPE REF TO cx_root.
|
|
|
|
FIELD-SYMBOLS: <lg_data> TYPE any,
|
|
<lg_field> TYPE any.
|
|
|
|
|
|
CREATE DATA lr_data TYPE ('ACM_S_DCLSRC').
|
|
ASSIGN lr_data->* TO <lg_data>.
|
|
|
|
TRY.
|
|
CALL METHOD ('CL_ACM_DCL_HANDLER_FACTORY')=>('CREATE')
|
|
RECEIVING
|
|
ro_handler = lo_dcl.
|
|
|
|
CALL METHOD lo_dcl->('READ')
|
|
EXPORTING
|
|
iv_dclname = ms_item-obj_name
|
|
IMPORTING
|
|
es_dclsrc = <lg_data>.
|
|
|
|
ASSIGN COMPONENT 'AS4USER' OF STRUCTURE <lg_data> TO <lg_field>.
|
|
ASSERT sy-subrc = 0.
|
|
CLEAR <lg_field>.
|
|
|
|
ASSIGN COMPONENT 'AS4DATE' OF STRUCTURE <lg_data> TO <lg_field>.
|
|
ASSERT sy-subrc = 0.
|
|
CLEAR <lg_field>.
|
|
|
|
ASSIGN COMPONENT 'AS4TIME' OF STRUCTURE <lg_data> TO <lg_field>.
|
|
ASSERT sy-subrc = 0.
|
|
CLEAR <lg_field>.
|
|
|
|
ASSIGN COMPONENT 'CREATED_BY' OF STRUCTURE <lg_data> TO <lg_field>.
|
|
ASSERT sy-subrc = 0.
|
|
CLEAR <lg_field>.
|
|
|
|
ASSIGN COMPONENT 'CREATED_DATE' OF STRUCTURE <lg_data> TO <lg_field>.
|
|
ASSERT sy-subrc = 0.
|
|
CLEAR <lg_field>.
|
|
|
|
ASSIGN COMPONENT 'AS4LOCAL' OF STRUCTURE <lg_data> TO <lg_field>.
|
|
ASSERT sy-subrc = 0.
|
|
CLEAR <lg_field>.
|
|
|
|
ASSIGN COMPONENT 'ABAP_LANGUAGE_VERSION' OF STRUCTURE <lg_data> TO <lg_field>.
|
|
IF sy-subrc = 0.
|
|
CLEAR <lg_field>.
|
|
ENDIF.
|
|
|
|
ASSIGN COMPONENT 'SOURCE' OF STRUCTURE <lg_data> TO <lg_field>.
|
|
ASSERT sy-subrc = 0.
|
|
|
|
mo_files->add_string( iv_ext = 'asdcls' iv_string = <lg_field> ).
|
|
|
|
CLEAR <lg_field>.
|
|
|
|
io_xml->add( iv_name = 'DCLS'
|
|
ig_data = <lg_data> ).
|
|
|
|
CATCH cx_root INTO lx_error.
|
|
zcx_abapgit_exception=>raise( iv_text = lx_error->get_text( )
|
|
ix_previous = lx_error ).
|
|
ENDTRY.
|
|
|
|
ENDMETHOD.
|
|
ENDCLASS.
|