mirror of
https://github.com/abapGit/abapGit.git
synced 2025-05-03 13:26:12 +08:00
f14ac831ba
* add global classes for objects * fix metadata * comment old code fix serializer class move missing interfaces * keep objects and bridge as local * fix syntax errors and remove SICF -> tadir dependency, instead tadir -> SICF * remove dependency TABL -> lcl_popups * fix indentation * remove old includes * fix parser errors * fix deserializing
265 lines
7.5 KiB
ABAP
265 lines
7.5 KiB
ABAP
CLASS zcl_abapgit_object_shi3 DEFINITION PUBLIC INHERITING FROM zcl_abapgit_objects_super FINAL.
|
|
|
|
PUBLIC SECTION.
|
|
INTERFACES zif_abapgit_object.
|
|
ALIASES mo_files FOR zif_abapgit_object~mo_files.
|
|
|
|
METHODS constructor
|
|
IMPORTING
|
|
is_item TYPE zif_abapgit_definitions=>ty_item
|
|
iv_language TYPE spras.
|
|
|
|
|
|
PRIVATE SECTION.
|
|
DATA: mv_tree_id TYPE ttree-id.
|
|
|
|
METHODS jump_se43
|
|
RAISING zcx_abapgit_exception.
|
|
|
|
|
|
|
|
METHODS clear_fields
|
|
CHANGING cs_head TYPE ttree
|
|
ct_nodes TYPE hier_iface_t.
|
|
|
|
ENDCLASS.
|
|
|
|
CLASS zcl_abapgit_object_shi3 IMPLEMENTATION.
|
|
|
|
METHOD zif_abapgit_object~has_changed_since.
|
|
rv_changed = abap_true.
|
|
ENDMETHOD. "zif_abapgit_object~has_changed_since
|
|
|
|
METHOD zif_abapgit_object~changed_by.
|
|
|
|
DATA: ls_head TYPE ttree.
|
|
|
|
CALL FUNCTION 'STREE_STRUCTURE_READ'
|
|
EXPORTING
|
|
structure_id = mv_tree_id
|
|
IMPORTING
|
|
structure_header = ls_head.
|
|
|
|
rv_user = ls_head-luser.
|
|
|
|
ENDMETHOD.
|
|
|
|
METHOD constructor.
|
|
super->constructor( is_item = is_item iv_language = iv_language ).
|
|
mv_tree_id = ms_item-obj_name.
|
|
ENDMETHOD. "constructor
|
|
|
|
METHOD zif_abapgit_object~get_metadata.
|
|
rs_metadata = get_metadata( ).
|
|
ENDMETHOD. "zif_abapgit_object~get_metadata
|
|
|
|
METHOD jump_se43.
|
|
|
|
DATA: lt_bdcdata TYPE TABLE OF bdcdata.
|
|
|
|
FIELD-SYMBOLS: <ls_bdcdata> LIKE LINE OF lt_bdcdata.
|
|
|
|
APPEND INITIAL LINE TO lt_bdcdata ASSIGNING <ls_bdcdata>.
|
|
<ls_bdcdata>-program = 'SAPLBMEN'.
|
|
<ls_bdcdata>-dynpro = '0200'.
|
|
<ls_bdcdata>-dynbegin = abap_true.
|
|
|
|
APPEND INITIAL LINE TO lt_bdcdata ASSIGNING <ls_bdcdata>.
|
|
<ls_bdcdata>-fnam = 'BDC_OKCODE'.
|
|
<ls_bdcdata>-fval = '=SHOW'.
|
|
|
|
APPEND INITIAL LINE TO lt_bdcdata ASSIGNING <ls_bdcdata>.
|
|
<ls_bdcdata>-fnam = 'BMENUNAME-ID'.
|
|
<ls_bdcdata>-fval = ms_item-obj_name.
|
|
|
|
CALL FUNCTION 'ABAP4_CALL_TRANSACTION'
|
|
STARTING NEW TASK 'GIT'
|
|
EXPORTING
|
|
tcode = 'SE43'
|
|
mode_val = 'E'
|
|
TABLES
|
|
using_tab = lt_bdcdata
|
|
EXCEPTIONS
|
|
system_failure = 1
|
|
communication_failure = 2
|
|
resource_failure = 3
|
|
OTHERS = 4.
|
|
|
|
IF sy-subrc <> 0.
|
|
zcx_abapgit_exception=>raise( 'error from ABAP4_CALL_TRANSACTION, SHI3' ).
|
|
ENDIF.
|
|
|
|
ENDMETHOD. "jump_se43
|
|
|
|
METHOD zif_abapgit_object~jump.
|
|
|
|
DATA: ls_head TYPE ttree.
|
|
|
|
CALL FUNCTION 'STREE_STRUCTURE_READ'
|
|
EXPORTING
|
|
structure_id = mv_tree_id
|
|
IMPORTING
|
|
structure_header = ls_head.
|
|
|
|
CASE ls_head-type.
|
|
WHEN 'BMENU'.
|
|
jump_se43( ).
|
|
WHEN OTHERS.
|
|
zcx_abapgit_exception=>raise( |Jump for type { ls_head-type } not implemented| ).
|
|
ENDCASE.
|
|
|
|
ENDMETHOD. "jump
|
|
|
|
METHOD zif_abapgit_object~exists.
|
|
|
|
DATA: ls_msg TYPE hier_mess,
|
|
ls_header TYPE ttree,
|
|
ls_tadir TYPE tadir.
|
|
|
|
CALL FUNCTION 'STREE_STRUCTURE_EXIST'
|
|
EXPORTING
|
|
structure_id = mv_tree_id
|
|
do_not_read_devclass = ''
|
|
IMPORTING
|
|
message = ls_msg
|
|
structure_header = ls_header
|
|
structure_tadir = ls_tadir.
|
|
|
|
rv_bool = boolc( ls_header-id IS NOT INITIAL ).
|
|
|
|
ENDMETHOD. "zif_abapgit_object~exists
|
|
|
|
METHOD zif_abapgit_object~delete.
|
|
|
|
CALL FUNCTION 'BMENU_DELETE_TREE'
|
|
EXPORTING
|
|
tree_id = mv_tree_id
|
|
EXCEPTIONS
|
|
trees_do_not_exist = 1
|
|
no_authority = 2
|
|
canceled = 3
|
|
OTHERS = 4.
|
|
IF sy-subrc <> 0.
|
|
zcx_abapgit_exception=>raise( 'error from BMENU_DELETE_TREE, SHI3' ).
|
|
ENDIF.
|
|
|
|
ENDMETHOD. "delete
|
|
|
|
METHOD zif_abapgit_object~serialize.
|
|
|
|
DATA: ls_msg TYPE hier_mess,
|
|
ls_head TYPE ttree,
|
|
lt_titles TYPE TABLE OF ttreet,
|
|
lt_nodes TYPE TABLE OF hier_iface,
|
|
lt_texts TYPE TABLE OF hier_texts,
|
|
lt_refs TYPE TABLE OF hier_ref.
|
|
|
|
|
|
CALL FUNCTION 'STREE_STRUCTURE_READ'
|
|
EXPORTING
|
|
structure_id = mv_tree_id
|
|
IMPORTING
|
|
message = ls_msg
|
|
structure_header = ls_head
|
|
TABLES
|
|
description = lt_titles.
|
|
|
|
CALL FUNCTION 'STREE_HIERARCHY_READ'
|
|
EXPORTING
|
|
structure_id = mv_tree_id
|
|
read_also_texts = 'X'
|
|
all_languages = 'X'
|
|
IMPORTING
|
|
message = ls_msg
|
|
TABLES
|
|
list_of_nodes = lt_nodes
|
|
list_of_references = lt_refs
|
|
list_of_texts = lt_texts.
|
|
|
|
clear_fields( CHANGING cs_head = ls_head
|
|
ct_nodes = lt_nodes ).
|
|
|
|
io_xml->add( iv_name = 'TREE_HEAD'
|
|
ig_data = ls_head ).
|
|
io_xml->add( iv_name = 'TREE_TITLES'
|
|
ig_data = lt_titles ).
|
|
io_xml->add( iv_name = 'TREE_NODES'
|
|
ig_data = lt_nodes ).
|
|
io_xml->add( iv_name = 'TREE_REFS'
|
|
ig_data = lt_refs ).
|
|
io_xml->add( iv_name = 'TREE_TEXTS'
|
|
ig_data = lt_texts ).
|
|
|
|
ENDMETHOD. "serialize
|
|
|
|
METHOD clear_fields.
|
|
|
|
FIELD-SYMBOLS <ls_node> LIKE LINE OF ct_nodes.
|
|
|
|
CLEAR: cs_head-luser, cs_head-ldate, cs_head-ltime.
|
|
CLEAR: cs_head-fuser, cs_head-fdate, cs_head-ftime.
|
|
CLEAR: cs_head-frelease, cs_head-lrelease.
|
|
CLEAR: cs_head-responsibl.
|
|
|
|
LOOP AT ct_nodes ASSIGNING <ls_node>.
|
|
CLEAR: <ls_node>-luser, <ls_node>-ldate, <ls_node>-ltime.
|
|
CLEAR: <ls_node>-fuser, <ls_node>-fdate, <ls_node>-ftime.
|
|
CLEAR: <ls_node>-frelease, <ls_node>-lrelease.
|
|
ENDLOOP.
|
|
|
|
ENDMETHOD. "strip_stamps
|
|
|
|
METHOD zif_abapgit_object~deserialize.
|
|
|
|
DATA: ls_msg TYPE hier_mess,
|
|
ls_head TYPE ttree,
|
|
lt_titles TYPE TABLE OF ttreet,
|
|
lt_nodes TYPE TABLE OF hier_iface,
|
|
lt_texts TYPE TABLE OF hier_texts,
|
|
lt_refs TYPE TABLE OF hier_ref.
|
|
|
|
io_xml->read( EXPORTING iv_name = 'TREE_HEAD'
|
|
CHANGING cg_data = ls_head ).
|
|
io_xml->read( EXPORTING iv_name = 'TREE_TITLES'
|
|
CHANGING cg_data = lt_titles ).
|
|
io_xml->read( EXPORTING iv_name = 'TREE_NODES'
|
|
CHANGING cg_data = lt_nodes ).
|
|
io_xml->read( EXPORTING iv_name = 'TREE_REFS'
|
|
CHANGING cg_data = lt_refs ).
|
|
io_xml->read( EXPORTING iv_name = 'TREE_TEXTS'
|
|
CHANGING cg_data = lt_texts ).
|
|
|
|
IF zif_abapgit_object~exists( ) = abap_true.
|
|
zif_abapgit_object~delete( ).
|
|
ENDIF.
|
|
|
|
CALL FUNCTION 'STREE_HIERARCHY_SAVE'
|
|
EXPORTING
|
|
structure_id = mv_tree_id
|
|
structure_type = ls_head-type
|
|
structure_description = space
|
|
structure_masterlanguage = mv_language
|
|
structure_responsible = sy-uname
|
|
development_class = iv_package
|
|
IMPORTING
|
|
message = ls_msg
|
|
TABLES
|
|
list_of_nodes = lt_nodes
|
|
list_of_references = lt_refs
|
|
list_of_texts = lt_texts
|
|
structure_descriptions = lt_titles
|
|
EXCEPTIONS
|
|
no_nodes_given = 1
|
|
OTHERS = 2.
|
|
IF sy-subrc <> 0.
|
|
zcx_abapgit_exception=>raise( 'Error from STREE_HIERARCHY_SAVE, SHI3' ).
|
|
ENDIF.
|
|
|
|
ENDMETHOD. "deserialize
|
|
|
|
METHOD zif_abapgit_object~compare_to_remote_version.
|
|
CREATE OBJECT ro_comparison_result TYPE zcl_abapgit_comparison_null.
|
|
ENDMETHOD.
|
|
|
|
ENDCLASS. "zcl_abapgit_object_shi3 IMPLEMENTATION
|