mirror of
https://github.com/abapGit/abapGit.git
synced 2025-05-02 04:36:49 +08:00
9f2db446b1
Since all object handler contains exactly the same CASE statement for STEP definition, I would recommend that each object handler simply returns the STEP he belongs to. This fix should "simply" issue #2499.
217 lines
4.7 KiB
ABAP
217 lines
4.7 KiB
ABAP
CLASS zcl_abapgit_object_doct DEFINITION PUBLIC INHERITING FROM zcl_abapgit_objects_super FINAL.
|
|
|
|
PUBLIC SECTION.
|
|
INTERFACES zif_abapgit_object.
|
|
ALIASES mo_files FOR zif_abapgit_object~mo_files.
|
|
|
|
PROTECTED SECTION.
|
|
PRIVATE SECTION.
|
|
CONSTANTS: c_id TYPE dokhl-id VALUE 'TX',
|
|
c_typ TYPE dokhl-typ VALUE 'E',
|
|
c_version TYPE dokhl-dokversion VALUE '0001',
|
|
c_name TYPE string VALUE 'DOC'.
|
|
|
|
TYPES: BEGIN OF ty_data,
|
|
doctitle TYPE dsyst-doktitle,
|
|
head TYPE thead,
|
|
lines TYPE tline_tab,
|
|
END OF ty_data.
|
|
|
|
METHODS: read
|
|
RETURNING VALUE(rs_data) TYPE ty_data.
|
|
|
|
ENDCLASS.
|
|
|
|
|
|
|
|
CLASS ZCL_ABAPGIT_OBJECT_DOCT IMPLEMENTATION.
|
|
|
|
|
|
METHOD read.
|
|
|
|
DATA: lv_object TYPE dokhl-object.
|
|
|
|
|
|
lv_object = ms_item-obj_name.
|
|
|
|
CALL FUNCTION 'DOCU_READ'
|
|
EXPORTING
|
|
id = c_id
|
|
langu = mv_language
|
|
object = lv_object
|
|
typ = c_typ
|
|
version = c_version
|
|
IMPORTING
|
|
doktitle = rs_data-doctitle
|
|
head = rs_data-head
|
|
TABLES
|
|
line = rs_data-lines.
|
|
|
|
ENDMETHOD.
|
|
|
|
|
|
METHOD zif_abapgit_object~changed_by.
|
|
rv_user = read( )-head-tdluser.
|
|
IF rv_user IS INITIAL.
|
|
rv_user = c_user_unknown.
|
|
ENDIF.
|
|
ENDMETHOD.
|
|
|
|
|
|
METHOD zif_abapgit_object~delete.
|
|
|
|
DATA: lv_object TYPE dokhl-object.
|
|
|
|
|
|
lv_object = ms_item-obj_name.
|
|
|
|
CALL FUNCTION 'DOCU_DEL'
|
|
EXPORTING
|
|
id = c_id
|
|
langu = mv_language
|
|
object = lv_object
|
|
typ = c_typ
|
|
EXCEPTIONS
|
|
ret_code = 1
|
|
OTHERS = 2.
|
|
IF sy-subrc <> 0.
|
|
zcx_abapgit_exception=>raise( 'error from DOCU_DEL' ).
|
|
ENDIF.
|
|
|
|
ENDMETHOD.
|
|
|
|
|
|
METHOD zif_abapgit_object~deserialize.
|
|
|
|
DATA: ls_data TYPE ty_data.
|
|
|
|
|
|
io_xml->read( EXPORTING iv_name = c_name
|
|
CHANGING cg_data = ls_data ).
|
|
|
|
CALL FUNCTION 'DOCU_UPDATE'
|
|
EXPORTING
|
|
head = ls_data-head
|
|
state = 'A'
|
|
typ = c_typ
|
|
version = c_version
|
|
TABLES
|
|
line = ls_data-lines.
|
|
|
|
tadir_insert( iv_package ).
|
|
|
|
ENDMETHOD.
|
|
|
|
|
|
METHOD zif_abapgit_object~exists.
|
|
|
|
DATA: lv_id TYPE dokil-id,
|
|
lv_object TYPE dokhl-object.
|
|
|
|
|
|
lv_object = ms_item-obj_name.
|
|
|
|
SELECT SINGLE id FROM dokil INTO lv_id
|
|
WHERE id = c_id
|
|
AND object = lv_object. "#EC CI_GENBUFF
|
|
|
|
rv_bool = boolc( sy-subrc = 0 ).
|
|
|
|
ENDMETHOD.
|
|
|
|
|
|
METHOD zif_abapgit_object~get_comparator.
|
|
RETURN.
|
|
ENDMETHOD.
|
|
|
|
|
|
METHOD zif_abapgit_object~get_deserialize_steps.
|
|
APPEND zif_abapgit_object=>gc_step_id-abap TO rt_steps.
|
|
ENDMETHOD.
|
|
|
|
|
|
METHOD zif_abapgit_object~get_metadata.
|
|
rs_metadata = get_metadata( ).
|
|
ENDMETHOD.
|
|
|
|
|
|
METHOD zif_abapgit_object~is_active.
|
|
rv_active = is_active( ).
|
|
ENDMETHOD.
|
|
|
|
|
|
METHOD zif_abapgit_object~is_locked.
|
|
rv_is_locked = abap_false.
|
|
ENDMETHOD.
|
|
|
|
|
|
METHOD zif_abapgit_object~jump.
|
|
|
|
DATA: ls_dokentry TYPE dokentry,
|
|
ls_bcdata TYPE bdcdata,
|
|
lt_bcdata TYPE STANDARD TABLE OF bdcdata.
|
|
|
|
" We need to modify dokentry directly, otherwise
|
|
" Batch Input on SE61 wouldn't work because it stores
|
|
" the last seen Document Class in this table. There's
|
|
" no standard function to do this. SE61 does this
|
|
" directly in its dialog modules
|
|
ls_dokentry-username = sy-uname.
|
|
ls_dokentry-langu = sy-langu.
|
|
ls_dokentry-class = c_id.
|
|
MODIFY dokentry FROM ls_dokentry.
|
|
|
|
ls_bcdata-program = 'SAPMSDCU'.
|
|
ls_bcdata-dynpro = '0100'.
|
|
ls_bcdata-dynbegin = 'X'.
|
|
APPEND ls_bcdata TO lt_bcdata.
|
|
|
|
CLEAR ls_bcdata.
|
|
ls_bcdata-fnam = 'RSDCU-OBJECT7'.
|
|
ls_bcdata-fval = ms_item-obj_name.
|
|
APPEND ls_bcdata TO lt_bcdata.
|
|
|
|
CLEAR ls_bcdata.
|
|
ls_bcdata-fnam = 'BDC_OKCODE'.
|
|
ls_bcdata-fval = '=SHOW'.
|
|
APPEND ls_bcdata TO lt_bcdata.
|
|
|
|
CALL FUNCTION 'ABAP4_CALL_TRANSACTION'
|
|
STARTING NEW TASK 'GIT'
|
|
EXPORTING
|
|
tcode = 'SE61'
|
|
mode_val = 'E'
|
|
TABLES
|
|
using_tab = lt_bcdata
|
|
EXCEPTIONS
|
|
OTHERS = 1.
|
|
|
|
IF sy-subrc <> 0.
|
|
zcx_abapgit_exception=>raise( 'error from ABAP4_CALL_TRANSACTION, DOCT' ).
|
|
ENDIF.
|
|
|
|
ENDMETHOD.
|
|
|
|
|
|
METHOD zif_abapgit_object~serialize.
|
|
|
|
DATA: ls_data TYPE ty_data.
|
|
|
|
|
|
ls_data = read( ).
|
|
|
|
CLEAR: ls_data-head-tdfuser,
|
|
ls_data-head-tdfreles,
|
|
ls_data-head-tdfdate,
|
|
ls_data-head-tdftime,
|
|
ls_data-head-tdluser,
|
|
ls_data-head-tdlreles,
|
|
ls_data-head-tdldate,
|
|
ls_data-head-tdltime.
|
|
|
|
io_xml->add( iv_name = c_name
|
|
ig_data = ls_data ).
|
|
|
|
ENDMETHOD.
|
|
ENDCLASS.
|