mirror of
https://github.com/abapGit/abapGit.git
synced 2025-05-01 12:20:51 +08:00
01dce88475
* Interface and implementing class in same package * Interface and implementing class in same package Co-authored-by: Lars Hvam <larshp@hotmail.com>
184 lines
4.6 KiB
ABAP
184 lines
4.6 KiB
ABAP
CLASS zcl_abapgit_version DEFINITION
|
|
PUBLIC
|
|
FINAL
|
|
CREATE PUBLIC .
|
|
|
|
PUBLIC SECTION.
|
|
CLASS-METHODS normalize
|
|
IMPORTING
|
|
!iv_version TYPE string
|
|
RETURNING
|
|
VALUE(rv_version) TYPE string.
|
|
|
|
CLASS-METHODS conv_str_to_version
|
|
IMPORTING
|
|
!iv_version TYPE csequence
|
|
RETURNING
|
|
VALUE(rs_version) TYPE zif_abapgit_definitions=>ty_version
|
|
RAISING
|
|
zcx_abapgit_exception.
|
|
|
|
CLASS-METHODS check_dependant_version
|
|
IMPORTING
|
|
!is_current TYPE zif_abapgit_definitions=>ty_version
|
|
!is_dependant TYPE zif_abapgit_definitions=>ty_version
|
|
RAISING
|
|
zcx_abapgit_exception.
|
|
|
|
PROTECTED SECTION.
|
|
PRIVATE SECTION.
|
|
ENDCLASS.
|
|
|
|
|
|
|
|
CLASS zcl_abapgit_version IMPLEMENTATION.
|
|
|
|
|
|
METHOD normalize.
|
|
|
|
" Internal program version should be in format "XXX.XXX.XXX" or "vXXX.XXX.XXX"
|
|
CONSTANTS:
|
|
lc_version_pattern TYPE string VALUE '^v?(\d{1,3}\.\d{1,3}\.\d{1,3})\s*$',
|
|
lc_prerelease_pattern TYPE string VALUE '^((rc|beta|alpha)\.\d{1,3})\s*$'.
|
|
|
|
DATA: lv_version TYPE string,
|
|
lv_prerelease TYPE string,
|
|
lv_version_n TYPE string,
|
|
lv_prerelease_n TYPE string.
|
|
|
|
SPLIT iv_version AT '-' INTO lv_version lv_prerelease.
|
|
|
|
FIND FIRST OCCURRENCE OF REGEX lc_version_pattern
|
|
IN lv_version SUBMATCHES lv_version_n.
|
|
|
|
IF lv_prerelease IS NOT INITIAL.
|
|
|
|
FIND FIRST OCCURRENCE OF REGEX lc_prerelease_pattern
|
|
IN lv_prerelease SUBMATCHES lv_prerelease_n.
|
|
|
|
ENDIF.
|
|
|
|
IF lv_version_n IS INITIAL.
|
|
RETURN.
|
|
ENDIF.
|
|
|
|
rv_version = lv_version_n.
|
|
|
|
IF lv_prerelease_n IS NOT INITIAL.
|
|
CONCATENATE rv_version '-' lv_prerelease_n INTO rv_version.
|
|
ENDIF.
|
|
|
|
ENDMETHOD.
|
|
|
|
|
|
METHOD conv_str_to_version.
|
|
|
|
DATA: lt_segments TYPE STANDARD TABLE OF string,
|
|
lt_parts TYPE STANDARD TABLE OF string,
|
|
lv_segment TYPE string.
|
|
|
|
SPLIT iv_version AT '-' INTO TABLE lt_segments.
|
|
|
|
READ TABLE lt_segments INTO lv_segment INDEX 1. " Version
|
|
IF sy-subrc <> 0. " No version
|
|
RETURN.
|
|
ENDIF.
|
|
|
|
SPLIT lv_segment AT '.' INTO TABLE lt_parts.
|
|
|
|
LOOP AT lt_parts INTO lv_segment.
|
|
|
|
TRY.
|
|
CASE sy-tabix.
|
|
WHEN 1.
|
|
rs_version-major = lv_segment.
|
|
WHEN 2.
|
|
rs_version-minor = lv_segment.
|
|
WHEN 3.
|
|
rs_version-patch = lv_segment.
|
|
ENDCASE.
|
|
CATCH cx_sy_conversion_no_number.
|
|
zcx_abapgit_exception=>raise( 'Incorrect format for Semantic Version' ).
|
|
ENDTRY.
|
|
|
|
ENDLOOP.
|
|
|
|
READ TABLE lt_segments INTO lv_segment INDEX 2. " Pre-release Version
|
|
IF sy-subrc <> 0. " No version
|
|
RETURN.
|
|
ENDIF.
|
|
|
|
SPLIT lv_segment AT '.' INTO TABLE lt_parts.
|
|
|
|
LOOP AT lt_parts INTO lv_segment.
|
|
|
|
CASE sy-tabix.
|
|
WHEN 1.
|
|
rs_version-prerelase = lv_segment.
|
|
TRANSLATE rs_version-prerelase TO LOWER CASE.
|
|
WHEN 2.
|
|
rs_version-prerelase_patch = lv_segment.
|
|
ENDCASE.
|
|
|
|
ENDLOOP.
|
|
|
|
IF rs_version-prerelase <> 'rc' AND rs_version-prerelase <> 'beta' AND rs_version-prerelase <> 'alpha'.
|
|
zcx_abapgit_exception=>raise( 'Incorrect format for Semantic Version' ).
|
|
ENDIF.
|
|
|
|
ENDMETHOD.
|
|
|
|
|
|
METHOD check_dependant_version.
|
|
|
|
CONSTANTS: lc_message TYPE string VALUE 'Current version is older than required'.
|
|
|
|
IF is_dependant-major > is_current-major.
|
|
zcx_abapgit_exception=>raise( lc_message ).
|
|
ELSEIF is_dependant-major < is_current-major.
|
|
RETURN.
|
|
ENDIF.
|
|
|
|
IF is_dependant-minor > is_current-minor.
|
|
zcx_abapgit_exception=>raise( lc_message ).
|
|
ELSEIF is_dependant-minor < is_current-minor.
|
|
RETURN.
|
|
ENDIF.
|
|
|
|
IF is_dependant-patch > is_current-patch.
|
|
zcx_abapgit_exception=>raise( lc_message ).
|
|
ELSEIF is_dependant-patch < is_current-patch.
|
|
RETURN.
|
|
ENDIF.
|
|
|
|
IF is_current-prerelase IS INITIAL.
|
|
RETURN.
|
|
ENDIF.
|
|
|
|
CASE is_current-prerelase.
|
|
WHEN 'rc'.
|
|
IF is_dependant-prerelase = ''.
|
|
zcx_abapgit_exception=>raise( lc_message ).
|
|
ENDIF.
|
|
|
|
WHEN 'beta'.
|
|
IF is_dependant-prerelase = '' OR is_dependant-prerelase = 'rc'.
|
|
zcx_abapgit_exception=>raise( lc_message ).
|
|
ENDIF.
|
|
|
|
WHEN 'alpha'.
|
|
IF is_dependant-prerelase = '' OR is_dependant-prerelase = 'rc' OR is_dependant-prerelase = 'beta'.
|
|
zcx_abapgit_exception=>raise( lc_message ).
|
|
ENDIF.
|
|
|
|
ENDCASE.
|
|
|
|
IF is_dependant-prerelase = is_current-prerelase AND is_dependant-prerelase_patch > is_current-prerelase_patch.
|
|
zcx_abapgit_exception=>raise( lc_message ).
|
|
ENDIF.
|
|
|
|
ENDMETHOD.
|
|
|
|
|
|
ENDCLASS.
|